Question

我有一个带有tsrange column的Postgres表格，我希望将其包含在我的Ecto模块schema中。我看到了Postgrex.Range exists。我试过这个：

schema "clients" do
  field :valid_at, Postgrex.Range
  ...
end

但是这给了我这个错误：

** (ArgumentError) invalid or unknown type Postgrex.Range for field :valid_at
    lib/ecto/schema.ex:1785: Ecto.Schema.check_type!/3
    lib/ecto/schema.ex:1473: Ecto.Schema.__field__/4

有什么建议吗？我使用Phoenix 1.3和Ecto master分支。

Answer 1

我认为你应该为tsrange创建一个自定义类型来使用Ecto。

defmodule YourApp.TimestampRange do
 @behaviour Ecto.Type

  def type, do: :tsrange

  def cast([lower, upper]) do
    {:ok, [lower, upper]}
  end

  def cast(_), do: :error 

  def load(%Postgrex.Range{lower: lower, upper: upper}) do
    {:ok, [lower, upper]}
  end

  def dump([lower, upper]) do
    {:ok, %Postgrex.Range{lower: lower, upper: upper, upper_inclusive: false}}
  end

  def dump(_), do: :error
end

关于包容性边界结帐PostgreSQL documentation

然后在您的应用中，您可以使用：

schema "clients" do
  field :valid_at, YourApp.TimestampRange
  ...
end

Answer 2

看起来@TheAnh有正确的方法，但实际上这是为我工作的：

defmodule Myapp.TsRange do
  @behaviour Ecto.Type

  def type, do: :tsrange

  def cast(nil),            do: {:ok, nil}
  def cast([lower, upper]), do: {:ok, [lower, upper]}
  def cast(_),              do: :error

  def load(%Postgrex.Range{lower: lower, upper: upper}) do
    lower = lower |> to_datetime
    upper = upper |> to_datetime
    case [lower, upper] do
      [nil, nil]                   -> {:ok, [nil, nil]}
      [{:ok, lower}, {:ok, upper}] -> {:ok, [lower, upper]}
      _ -> :error
    end
  end
  def load(_), do: :error

  def dump([lower, upper]) do
    {:ok, %Postgrex.Range{lower: lower |> from_datetime,
                          upper: upper |> from_datetime,
                          upper_inclusive: false}}
  end
  def dump(_), do: :error

  defp to_datetime(nil), do: nil
  defp to_datetime({{y, m, d}, {h, min, s, ms}}) do
    NaiveDateTime.new(y, m, d, h, min, s, ms)
  end

  defp from_datetime(nil), do: nil
  defp from_datetime(dt) do
    {{dt.year, dt.month, dt.day}, {dt.hour, dt.minute, dt.second, elem(dt.microsecond, 0)}}
  end

end

带有tsrange字段的Ecto模式

2 个答案: