Question

所以我最终决定咬紧牙关并重写我公司的可怕的 Trace32脚本。我正在尝试使用数据文件来保存运行之间的相关信息，因此我们可以运行重做脚本来重复任何操作，而无需导航一堆对话框并在每个电源循环后选择我们的工作区文件。为了做到这一点，我需要将用户定义的变量从之前的运行（包括文件位置）保存到文件中，以便我在下次运行时使用它们。作为参考，这是我的菜单脚本的一部分。

; File: Do.cmm
GLOBAL &WORKSPACE
GLOBAL &FILETOLOAD
GLOBAL &TARGETSELVAL

&WORKSPACE="//tsclient\Z\Product_trunk_MS" ; Not the ideal solution

PRINT "Workspace is &WORKSPACE"

DIALOG
(
    HEADER "Do one of the following"

    POS 0. 0. 23.
    COMMAND.PREVIOUS: CHOOSEBOX "Repeat Last Command" ""
    POS 24. 0. 23.
    COMMAND.WORKSPACE: CHOOSEBOX "Change Workspace Location" ""

    POS 0. 3. 25.
    TEXT "Connect To an R7 Proc:"
    POS 0. 4. 6.
    COMMAND.IP0: CHOOSEBOX "IP0" ""
    POS 8. 4. 7.
    COMMAND.IP1: CHOOSEBOX "IP1" ""

    ; And a lot more of the same...

    POS 17. 16. 15.
    DEFBUTTON "OK" "continue"
)
DIALOG.SET COMMAND.PREVIOUS
STOP

IF DIALOG.BOOLEAN(COMMAND.IP0)
(
 &TARGETSELVAL=0x00030000
 &FILETOLOAD="&WORKSPACE\CPUs\IP0\build\output\IP0.axf"
)
IF DIALOG.BOOLEAN(COMMAND.IP1)
(
 &TARGETSELVAL=0x0003001
 &FILETOLOAD=&WORKSPACE\CPUs\IP1\build\output\IP1.axf
)
... And so on

这个问题是我每次更改工作区时都必须编辑脚本。我希望能够通过选择COMMAND.PREVIOUS，然后使用Windows选择对话框选择我的新工作区根目录，在上面的脚本中设置它。我没有该功能的工作实现，但我希望它看起来像这样：

IF DIALOG.BOOLEAN(COMMAND.WORKSPACE)
(
    PRINT "Select the new root directory that you would like to work out of."
    OPEN  #1 workspace.dat /Create
    &WORKSPACE= C/*/ ; I don't know how to do this here.
    WRITE #1 &WORKSPACE
    CLOSE #1
    ENDDO
)

显然，Data.load.binary "*.bin"能够将文件加载到内存中，但我还不需要加载文件，我只想要路径。我确实发现symbol.SOURCEPATH.SETBASEDIR c:\*会打开一个对话框，但我仍然无法获取该信息。

其他信息

在尝试寻找解决方案时，我已阅读了很多this和this。如果我应该使用内置路径变量（如前面提到的SOURCEPATH.SETBASEDIR，我不介意这样做。这是我写Trace32脚本的第一天，所以我提前为我的天真道歉。如果重要的话，我使用Trace32 Powerview for ARM Release 2017年2月SP2（32位）（那么，最新的）

Answer 1

我最终找到了一个与xasc有点不同的问题解决方案，所以我想我会分享它。

IF DIALOG.BOOLEAN(COMMAND.WORKSPACE)
(
    PRINT "Select the new root directory that you would like to work out of."
    DIALOG.DIR *
    ENTRY %LINE &WORKSPACE

    OPEN  #1 workspace.dat /Create
    WRITE #1 "&WORKSPACE"
    CLOSE #1
)

这对我的目的来说有点干净，因为它并不要求我更改工作目录。 DIALOG似乎是我正在寻找的界面，能够打开文件，目录等，并将它们保存到变量中。

Trace32将目录位置写入文件

1 个答案: