Question

我想要使用协议缓冲区（gRPC）进行通信的3个java应用程序（后端，前端和Android应用程序）。所以我希望3个应用程序都可以访问共享的protobuf repo（Github），在那里我管理.proto文件。我是使用Gradle和protobufs的新手，所以我不确定管理这个的正确方法是什么，任何帮助或指导都会受到赞赏。我可以让每个Gradle项目声明我的github protobuf repo作为依赖项，然后在构建项目时将其下拉并编译它吗？我认为这样做是一种很好的方式，而不是存储已编译的protobuf类，因为Android应用程序可能需要一个不同的＆＃34; Java-lite＆＃34; protobufs的版本？我正在使用google / protobuf-gradle-plugin来编译.proto文件，并查看从本地文件编译的文档，或者提取具有预编译.proto文件的项目，但没有用于提取远程.proto文件的文档。我是在正确的轨道上吗？

Answer 1

你的远程.proto文件/ repo是什么形式的？如果它只是一个网址，那么您可以使用下载任务：

buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath 'com.google.protobuf:protobuf-gradle-plugin:0.8.0'
    }
}

plugins {
    id "de.undercouch.download" version "3.2.0"
}

group 'testtest'
version '1.0-SNAPSHOT'

apply plugin: 'java'
apply plugin: 'com.google.protobuf'


sourceCompatibility = 1.8

repositories {
    mavenCentral()
}

task downloadFile << {
    download {
        src 'https://raw.githubusercontent.com/grpc/grpc-java/master/compiler/src/test/proto/test.proto'
        dest "$projectDir/src/main/proto/test.proto"
        overwrite true
    }
}

build.dependsOn downloadFile

dependencies {
    compile "io.grpc:grpc-protobuf-lite:1.5.0"
    compile "io.grpc:grpc-stub:1.5.0"
}

protobuf {
    protoc {
        artifact = 'com.google.protobuf:protoc:3.3.0'
    }
    plugins {
        javalite {
            artifact = "com.google.protobuf:protoc-gen-javalite:3.0.0"
        }
        grpc {
            artifact = "io.grpc:protoc-gen-grpc-java:1.5.0"
        }
    }
    generateProtoTasks {
        all().each { task ->
            task.builtins {
                remove java
            }
            task.plugins {
                javalite {}
                grpc {
                    option 'lite'
                }
            }
        }
    }
}

管理共享协议缓冲区库并使用Gradle进行编译

1 个答案: