Question

我对此问题几乎有同样的问题：Get value after each last colon。在我的情况下，我需要迭代每次出现：A：和：B：，：B：是孩子：A：。在我的代码中，我使用的是一个我不太熟悉的调用模板。但是，我需要探索xslt中的其他功能/元素。

以下是我的示例测试文件：

<Record>
:A:This is sample only 1
:B:This is sample only 2
:B:This is sample only 3
:A:This is sample only 4
:B:This is sample only 5
</Record>

预期产出：

<Record>
  <Detail>
    <FieldA>This is sample only 1</FieldA>
    <Trans>
      <Group>
        <FieldB>This is sample only 2</FieldB>
      </Group>
      <Group>
        <FieldB>This is sample only 3</FieldB>
      </Group>
    </Trans>
  </Detail>
  <Detail>
    <FieldA>This is sample only 4</FieldA>
    <Trans>
      <Group>
        <FieldB>This is sample only 5</FieldB>
      </Group>
    </Trans>
  </Detail>
<Record>

对于每次出现的：A：，我需要创建一个<Detail>记录，然后为每个记录创建：B：将创建一个<Group>记录。这是我的XSLT代码，

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
<xsl:output method="xml" version="1.0" indent="yes"/>
<xsl:template match="node()|@*">
    <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
</xsl:template>
<xsl:template match="Record">
    <xsl:call-template name="FormatXML">
        <xsl:with-param name="Input">
            <Record>
            <xsl:for-each select="tokenize(.,':A:')">
                <xsl:analyze-string select="." regex=":([0-9A-Za-z]+):(.*)\n">
                    <xsl:matching-substring>
                        <xsl:variable name="FieldA">
                            <xsl:if test="regex-group(1) = 'A'">
                                <FieldB>
                                    <xsl:value-of select="regex-group(2)"/>
                                </FieldB>
                            </xsl:if> 
                        </xsl:variable>
                        <xsl:for-each select="tokenize(.,':B:')">
                        <xsl:variable name="FieldB">
                            <xsl:if test="regex-group(1) = 'B'">
                                <FieldB>
                                    <xsl:value-of select="regex-group(2)"/>
                                </FieldB>
                            </xsl:if> 
                        </xsl:variable>
                        <Group>
                            <FieldB>
                                <xsl:value-of select="$FieldB"/>
                            </FieldB>
                        </Group>
                        </xsl:for-each>
                        <Detail>
                            <FieldA>
                                <xsl:value-of select="$FieldA"/>
                            </FieldA>
                        </Detail>
                    </xsl:matching-substring>
                </xsl:analyze-string>                
            </xsl:for-each>
            </Record>
        </xsl:with-param>
    </xsl:call-template>
</xsl:template>
<xsl:template name="FormatXML">
    <xsl:param name="Input"/>
    <xsl:apply-templates select="$Input"/>    
</xsl:template>
<xsl:template match="/Record">
    <xsl:copy>
        <xsl:apply-templates select="Detail"/>
    </xsl:copy>
</xsl:template>
<xsl:template match="Detail">
    <xsl:copy>
        <xsl:copy-of select="FieldA"/>
        <Trans>
            <xsl:apply-templates select="Group"/>
        </Trans>
    </xsl:copy>
</xsl:template>
<xsl:template match="Group">
    <xsl:copy>
        <xsl:apply-templates select="FieldB"/>
    </xsl:copy>
</xsl:template>

我的xslt代码无效。如果在我的代码中遗漏了什么，任何人都可以帮助我。非常感谢您的反馈。

谢谢！

Answer 1

我建议采用一种截然不同的方法：首先将字符串转换为单个元素，这样就可以了：

<FieldA>This is sample only 1</FieldA>
<FieldB>This is sample only 2</FieldB>
<FieldB>This is sample only 3</FieldB>
<FieldA>This is sample only 4</FieldA>
<FieldB>This is sample only 5</FieldB>

在一个变量中。

然后将变量中的元素分组并按照您希望的方式输出：

XSLT 2.0

<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="Record">
    <!-- convert strings to elements -->
    <xsl:variable name="temp" as="element()*">
        <xsl:analyze-string select="." regex="^:([AB]):(.*)$" flags="m">
            <xsl:matching-substring>
                <xsl:element name="Field{regex-group(1)}">
                    <xsl:value-of select="regex-group(2)" />
                </xsl:element>
            </xsl:matching-substring>
        </xsl:analyze-string>
    </xsl:variable>
    <!-- output  -->
    <xsl:copy>
        <!-- group elements -->
        <xsl:for-each-group select="$temp" group-starting-with="FieldA">
            <Detail>
                <xsl:copy-of select="current-group()[1]" />
                <Trans>
                    <xsl:for-each select="current-group()[position() ge 2]">
                        <Group>
                            <xsl:copy-of select="." />
                        </Group>
                    </xsl:for-each>
                </Trans>
            </Detail>
        </xsl:for-each-group>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

演示：http://xsltransform.net/gVhD8Ro/1

Answer 2

使用XSLT 3.0（由Saxon 9.8所有版本支持）或Altova XMLSpy和Raptor，您可以直接对这些行进行分组：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:math="http://www.w3.org/2005/xpath-functions/math" exclude-result-prefixes="xs math"
    expand-text="true" version="3.0">

    <xsl:output indent="yes"/>

    <xsl:template match="Record">
        <xsl:copy>
            <xsl:for-each-group select="tokenize(., '\r?\n')[normalize-space()]"
                group-starting-with=".[starts-with(., ':A:')]">
                <Detail>
                    <FieldA>{replace(., ':A:', '')}</FieldA>
                    <Trans>
                        <xsl:apply-templates select="current-group()[position() gt 1]"/>
                    </Trans>
                </Detail>
            </xsl:for-each-group>
        </xsl:copy>
    </xsl:template>

    <xsl:template match=".[starts-with(., ':B:')]">
        <Group>
            <FieldB>{replace(., ':B:', '')}</FieldB>
        </Group>
    </xsl:template>

</xsl:stylesheet>

获取冒号后的值 - 键

2 个答案: