Question

晚上好，

我在使用XSL-T 3.0将“parse-xml-fragment”的结果传递给模板时遇到问题。我使用的是Saxon-PE 9.7.0.15（Java版本捆绑在最新的oXygen 19中）。我希望能够将已经定义的模板应用于“parse-xml-fragment”生成的“document-node”，就像它是原始XML文档的一部分而不是一个已定义属性的base64内容一样。换句话说，我需要浏览“parse-xml-fragment”结果的未知内容。

我可以使用例如

从base64内容中获取值

<xsl:value-of select="parse-xml-fragment(saxon:base64Binary-to-string(./@a, 'UTF-8'))/base64Root/a/@at"/>

但它假设，我知道给定属性的base64值的结构和内容，我不知道。

XML文件是：

<?xml version="1.0" encoding="UTF-8"?>
<?xml-stylesheet type="text/xsl" href="a.xsl"?>
<root a="PGJhc2U2NFJvb3Q+PGEgYXQ9IjEiPjwvYT48YiBhdD0iMiI+PC9iPjwvYmFzZTY0Um9vdD4="/>
<!-- 
  content of @a is (and may vary in structure and content): 
  <base64Root><a at="1"></a><b at="2"></b></base64Root>
-->

XSL-T 3.0文件（无法正常工作）是：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" xmlns:saxon="http://saxon.sf.net/" exclude-result-prefixes="xs" version="3.0">

  <xsl:output method="text" />

  <xsl:template match="/root">
    <xsl:call-template name="anyElement">
      <xsl:with-param name="xmlFragment" select="parse-xml-fragment(saxon:base64Binary-to-string(./@a, 'UTF-8'))"/>
    </xsl:call-template>
  </xsl:template>

  <xsl:template name="anyElement" match="*">
    <xsl:param name="xmlFragment"/>
    <xsl:value-of select="local-name(.)"/>
    <xsl:value-of select="./@at"/>
    <xsl:apply-templates>
      <xsl:with-param name="xmlFragment" select="."/>
    </xsl:apply-templates>
  </xsl:template>

</xsl:stylesheet>

所需的输出就像（格式化现在并不重要）：

root 
PGJhc2U2NFJvb3Q+PGEgYXQ9IjEiPjwvYT48YiBhdD0iMiI+PC9iPjwvYmFzZTY0Um9vdD4=
base64Root
a
1
b
2

非常感谢您的帮助。斯泰潘

Answer 1

我只是将带有apply-templates的节点推送到模板匹配元素节点，我不知道为什么你首先调用模板：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    xmlns:math="http://www.w3.org/2005/xpath-functions/math"
    xmlns:saxon="http://saxon.sf.net/"
    exclude-result-prefixes="xs math saxon"
    version="3.0">

    <xsl:output method="text" />

    <xsl:template match="/root">
        <xsl:next-match/>
        <xsl:apply-templates select="parse-xml-fragment(saxon:base64Binary-to-string(@a, 'UTF-8'))/node()"/>
    </xsl:template>

    <xsl:template match="*">
        <xsl:value-of select="local-name(), @*" separator="&#10;"/>
        <xsl:text>&#10;</xsl:text>
        <xsl:apply-templates/>   
    </xsl:template>

</xsl:stylesheet>

输出

root
PGJhc2U2NFJvb3Q+PGEgYXQ9IjEiPjwvYT48YiBhdD0iMiI+PC9iPjwvYmFzZTY0Um9vdD4=
base64Root
a
1
b
2

如何使用XSLT 3使用模板遍历parse-xml-fragment结果的未知内容？

1 个答案: