Question

自从雅虎融资改为不支持自动下载后，我检查了其他来源，www.alphavantage.co似乎符合我的要求。但是，数据没有达到excel。那里的人有没有编程呢？我使用的测试链接是https://www.alphavantage.co/query?function=TIME_SERIES_DAILY_ADJUSTED&symbol=MSFT&apikey=demo&datatype=csv。它在浏览器中打开时将数据下载到csv文件中，但没有数据到达excel。

非常感谢，扬

Answer 1

在VBA中，选择工具＆gt;参考文献并选择以下参考文献：

Microsoft Script Control 1.0
Microsoft Scripting Runtime

以下函数将检索特定符号的最新数据（打开，高，低，关闭和音量）：

Public Function GetLastCloseData(symbol As String) As Dictionary
    Dim scriptControl As Object
    Dim json As Object
    Dim time_series As Object
    Dim date_data As Object
    Dim date_label As String
    Dim date_offset As Integer

    Set scriptControl = CreateObject("MSScriptControl.ScriptControl")
    scriptControl.Language = "JScript"

    'Retrieve historical price data in JSON format
    With CreateObject("MSXML2.XMLHTTP")
        .Open "GET", "https://www.alphavantage.co/query?function=TIME_SERIES_DAILY&symbol=" & symbol & "&apikey=" & API_KEY, False
        .send
        Set json = scriptControl.Eval("(" + .responseText + ")")
        .abort
    End With

    'CallByName returns an error if it cannot find the requested selection.
    'The code is written to skip over those errors.
    On Error Resume Next

    Set time_series = CallByName(json, "Time Series (Daily)", VbGet)

    'If time series property was found...
    If Not time_series Is Nothing Then
        date_offset = 0
        'Retrieve the most recent closing price by looking for todays date. If it's not found,
        'iterate through the last week of dates, stopping whenever the most recent is found.
        While date_data Is Nothing And date_offset < 8
            date_label = Format(DateAdd("d", -date_offset, Date), "yyyy-mm-dd")
            Set date_data = CallByName(time_series, date_label, VbGet)
            date_offset = date_offset + 1
        Wend
    End If

    If Not date_data Is Nothing Then
        Set GetLastCloseData = New Dictionary
        With GetLastCloseData
            .Add "Open", CDbl(CallByName(date_data, "1. open", VbGet))
            .Add "High", CDbl(CallByName(date_data, "2. high", VbGet))
            .Add "Low", CDbl(CallByName(date_data, "3. low", VbGet))
            .Add "Close", CDbl(CallByName(date_data, "4. close", VbGet))
            .Add "Volume", CLng(CallByName(date_data, "5. volume", VbGet))
        End With
    End If

    'set error handling back to normal
    On Error GoTo 0

End Function

以下Sub演示了如何使用结果：

Public Sub GetStockData()
    Dim daily_data As Dictionary

    Set daily_data = GetLastCloseData("SPY")
    Debug.Print daily_data("Open")
    Debug.Print daily_data("High")
    Debug.Print daily_data("Low")
    Debug.Print daily_data("Close")
    Debug.Print daily_data("Volume")
End Sub

输出：

将库存数据从www.alphavantage.co下载到excel

1 个答案: