Question

您能否举例说明retag参数如何影响multi-spec创建？我发现multi-spec文档难以消化。

Answer 1

来自docstring：

在生成期间使用retag来重新生成生成的值匹配标签。 retag可以是关键字，也可以是关键字 dispatch-tag将被关联，或者生成值的fn和 dispatch-tag应返回适当重新标记的值。

如果retag是关键字（如spec guide example中所述），multi-spec会在内部创建一个在生成器实现函数中使用的函数here。例如，这两个多规范声明在功能上是等效的：

(s/def :event/event (s/multi-spec event-type :event/type))
(s/def :event/event (s/multi-spec event-type
                                  (fn [genv tag]
                                    (assoc genv :event/type tag))))

根据指南的示例，传递retag 函数似乎不是一个非常有用的选项，但在将multi-spec用于非地图时更有用。例如，如果您想将multi-spec与s/cat一起使用，例如到spec函数args：

(defmulti foo first)
(defmethod foo :so/one [_]
  (s/cat :typ #{:so/one} :num number?))
(defmethod foo :so/range [_]
  (s/cat :typ #{:so/range} :lo number? :hi number?))

foo取两个或三个args，具体取决于第一个arg。如果我们使用multi-spec关键字/标记天真地尝试s/cat，则无效：

(s/def :so/foo (s/multi-spec foo :typ))
(sgen/sample (s/gen :so/foo))
;; ClassCastException clojure.lang.LazySeq cannot be cast to clojure.lang.Associative

这是能够传递retag函数的地方很有用：

(s/def :so/foo (s/multi-spec foo (fn [genv _tag] genv)))
(sgen/sample (s/gen :so/foo))
;=>
;((:so/one -0.5)
; (:so/one -0.5)
; (:so/range -1 -2.0)
; (:so/one -1)
; (:so/one 2.0)
; (:so/range 1.875 -4)
; (:so/one -1)
; (:so/one 2.0)
; (:so/range 0 3)
; (:so/one 0.8125))

Answer 2

我同意文档很简洁！

我想生成一个带有标签的multi-spec d地图，该标签可能具有多个值。我发现传递给retag函数的第二个参数实际上是 dispatch 标签，而不是分配的标签（就像文档中所说的那样）。这导致s/gen仅生成使用（非默认）多方法分发选项标记的地图，而不使用标签规范所涵盖的完整范围。

(s/def ::tag #{:a :b :c :d})
(s/def ::example-key keyword?)
(s/def ::different-key keyword?)

(defmulti tagmm :tag)
(defmethod tagmm :a [_]
  (s/keys :req-un [::tag ::example-key]))
(defmethod tagmm :default [_] ; this is `defmulti`'s :default
  (s/keys :req-un [::tag ::different-key]))

(s/def ::example (s/multi-spec tagmm :tag))

(gen/sample (s/gen ::example))
;=> only gives examples with {:tag :a, ...}

提供retag只是忽略其第二个参数并返回生成的值使生成器按预期工作。

(s/def ::example (s/multi-spec tagmm (fn [gen-v tag] gen-v)))
;=> now gives examples from every ::tag

很难锻炼，但值得！

s / multi-spec中的retag参数是什么意思？

2 个答案: