如何在XSLT中获取特定.ODS单元格的任何类型的内容

Question

我正在尝试使用XSLT转换.ods文件（来自zip的content.xml文件），以便生成所需的.xml文件。

XSLT使用＆＃34;固定＆＃34;获取内容的元素位置，但在我的.ods文件中，我有很多空白字段，我不知道如何在XSLT中计算它们。

此外，我使用content.xml进行了一些实验，以确定是否保存了这些空白（空）单元格。

在content.xml我找到了类似的内容：

<table:table-column table:style-name="co1" table:number-columns-repeated="16384" table:default-cell-style-name="ce1"/>
<table:table-row table:number-rows-repeated="1048576" table:style-name="ro1">

这些值是否以某种方式（例如通过数学计算）表示.ods文件中值的空单元格或实际位置？

我在这里分享我的文件，让你有更明确的想法

.ods示例：

这是我的XSLT文件：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="2.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:xs="http://www.w3.org/2001/XMLSchema" 
xmlns:fn="http://www.w3.org/2005/xpath-functions" 
xmlns:office="urn:oasis:names:tc:opendocument:xmlns:office:1.0" 
xmlns:style="urn:oasis:names:tc:opendocument:xmlns:style:1.0" 
xmlns:table="urn:oasis:names:tc:opendocument:xmlns:table:1.0" 
xmlns:text="urn:oasis:names:tc:opendocument:xmlns:text:1.0" 
xmlns:espd="urn:com:grow:espd:02.00.00" xmlns:cac="urn:X-test:UBL:Pre-
award:CommonAggregate" xmlns:cbc="urn:X-test:UBL:Pre-award:CommonBasic" 


<xsl:output method="html" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="office:spreadsheet/table:table">
<xsl:variable name="test" select="table:table-row/table:table-cell"/>
<p><xsl:value-of select="$test/text:p[1]"/></p>
</xsl:template>

输出结果为：

  

burak burak5 burak6 burak2 burak3 burak4 burak7 burak9 burak8 burak10

问题：

如何通过在content.xml上应用转换来获取单元格中的单个值？ （例如：如何只获取单元格D4？）

Answer 1

  

如何通过在content.xml上应用转换来获取单元格中的单个值？

.ods文件的content.xml中的XML数据以这种方式编码（始终以table:命名空间为前缀）：

• 每个table-cell都包含在table-row s
中
• 空table-cell已编码为空RLE (Run-Length-Encoding)由number-columns-repeated="..."属性指示，必须跳过但计算
• 空table-row也用RLE编码，由number-rows-repeated="..."属性
表示
• table-columns似乎只在开头使用

因此，要获得特定的细胞，例如D4 = 4:4，必须计算包含跳过的table-row的内容：

D4 = 4:4 = Get the fourth `table-row`, add one cell D1, then add number-columns-repeated="2"

这是一些XSLT-1.0代码（也可用于2.0和3.0），其中包含GetCellValue个例子：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
xmlns:xs="http://www.w3.org/2001/XMLSchema" 
xmlns:fn="http://www.w3.org/2005/xpath-functions" 
xmlns:office="urn:oasis:names:tc:opendocument:xmlns:office:1.0" 
xmlns:style="urn:oasis:names:tc:opendocument:xmlns:style:1.0" 
xmlns:table="urn:oasis:names:tc:opendocument:xmlns:table:1.0" 
xmlns:text="urn:oasis:names:tc:opendocument:xmlns:text:1.0" 
xmlns:espd="urn:com:grow:espd:02.00.00" 
xmlns:cac="urn:X-test:UBL:Pre-award:CommonAggregate" 
xmlns:cbc="urn:X-test:UBL:Pre-award:CommonBasic" exclude-result-prefixes="xs fn office style table text espd cac cbc"> 

<xsl:output method="html" version="4.0" encoding="UTF-8" indent="yes"/>
<xsl:variable name="str" select="'x:1 y:4'" />             <!-- define some coord system -->


  <xsl:template match="/office:document-content/office:body/office:spreadsheet/table:table">
    Table dimensions: <xsl:call-template name="GetDimensions" />
    Value at 5x8: <xsl:call-template name="GetCellValue">
      <xsl:with-param name="x" select="5" />
      <xsl:with-param name="y" select="8" />
    </xsl:call-template>
    Value at 1x4: <xsl:call-template name="GetCellValue">  <!-- use string defined above -->
      <xsl:with-param name="x" select="substring-after(substring-before($str,' '),'x:')" />
      <xsl:with-param name="y" select="substring-after($str,'y:')" />
    </xsl:call-template>
  </xsl:template>

  <xsl:template name="GetCellValue">
    <xsl:param name="x" />
    <xsl:param name="y" />
    <xsl:variable name="targetRow" select="table:table-row[sum(preceding-sibling::*/@table:number-rows-repeated) + position() - count(preceding-sibling::*/@table:number-rows-repeated)= $y]" />
    <xsl:variable name="targetCell" select="$targetRow/table:table-cell[sum(preceding-sibling::*/@table:number-columns-repeated) + position() - count(preceding-sibling::*/@table:number-columns-repeated) &lt;= $x]" />
    <xsl:copy-of select="$targetCell[last()]/text:p/text()" />
  </xsl:template>

  <xsl:template name="GetDimensions">
    <xsl:variable name="firstRow" select="table:table-row[1]/table:table-cell" />
    <xsl:variable name="firstColumn" select="table:table-row" />
    <xsl:variable name="width" select="count($firstRow)+ sum($firstRow/@table:number-columns-repeated) - count($firstRow/@table:number-columns-repeated)" />
    <xsl:variable name="height" select="count($firstColumn)+ sum($firstColumn/@table:number-rows-repeated) - count($firstColumn/@table:number-rows-repeated)" />
    <xsl:value-of select="concat($width,'x',$height)" />
  </xsl:template>

</xsl:stylesheet>

输出为：

Table dimensions: 5x12
Value at 5x8: burak9
Value at 1x4: burak4

修改
我修改了一个xsl:call-template，用于自定义格式的字符串输入，例如x:1 y:4。

<强> EDIT2：
可以找到一个XSLT-2.0版本，可以一次检索多个单元格作为XML元素in this answer。