Question

我是VBA的新手，希望能够帮助实现用户定义的功能。我真的很感激任何帮助！

上下文：我正在尝试将一批固定宽度的文本文件导入到单独的Excel工作簿中。文本文件都具有相同的字段和格式。我知道每个领域的长度。目前，我正在尝试将我的VBA代码用于单个文本文件。

问题：由于我是VBA的新手，我查找了现有代码。我发现Chip Pearson's ImportFixedWidth function，edited one error found by another StackOverflow user，并且一直试图实现我的TestImport函数（见下文）。（*请注意......只是为了简洁起见 - 实际上并没有包含在代码中。）

Sub TestImport()
Dim L As Long
L = ImportFixedWidth("/Users/gitanjali/Desktop/CAC06075test.txt", _
    Range("A1"), _
    False, _
    vbNullString, _ 
    "1,5|2,45|3,3|4,45|5,45|6,45|7,60|8,15|9,11|10,60| _
                 11,60|12,10|13,5|14,5|15,3|16,3|17,3|18,3|19,11|20,10| 
                 ...190,250|191,250")
End Sub

请参阅本文末尾的ImportFixedWidth函数。

然后我尝试在工作簿中运行宏，但每次都会崩溃VBA和Excel。将第一个字段导入（而不是其他190）到打开的工作簿中，但程序停止响应并且必须退出。

调试：代码编译。单步执行TestImport或ImportFixedWidth代码时，我没有收到任何错误。我已经尝试在Mac和Windows PC上运行宏（它在两者上崩溃）。并且在程序崩溃之前正确导入第一个字段，所以我不确定问题是什么。

问题：我对调试方面的后续步骤感到茫然。我的实施中是否有任何明显的错误？我的下一个逻辑调试步骤是什么？

Function ImportFixedWidth(FileName As String, _
    StartCell As Range, _
    IgnoreBlankLines As Boolean, _
    SkipLinesBeginningWith As String, _
    ByVal FieldSpecs As String) As Long
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' ImportFixedWidth
' By Chip Pearson, chip@cpearson.com www.cpearson.com
' Date: 27-August-2011
' Compatible with 64-bit platforms.
'
' This function imports text from a fixed field width file.
' FileName is the name of the file to import. StartCell is
' the cell in which the import is to begin. IgnoreBlankLines
' indicates what to do with empty lines in the text file. If
' IgnoreBlankLines is False, an empty row will appear in the
' worksheet. If IgnoreBlankLines is True, no empty row will
' appear in the worksheet. SkipLinesBeginingWith indicates
' what character, if any, at the begining of the line indicates
' that the line should not be imported, such as fpr providing for
' comments within the text file. FieldSpecs indicates how to
' map the data into cells. It is a string of the format:
'           start,length|start,length|start,length...
' where each 'start' is the character position of the field
' in the text line and each 'length' is the length of the field.
' For example, if FieldSpecs is
'           1,8|9,3|12,5
' indicates the first field starting in position 1 for a
' length of 8, the second field starts in position 9 for a
' length of 3, and finally a field beginning in position 12
' for a length of 5. Fields can be in any order and may
' overlap.
' You can specify a number format for the field which will
' be applied to the worksheet cell. This format should not
' be in quotes and should follow the length element. For example,
'       2,8|9,3,@|12,8,dddd dd-mmm-yyyy
' This specifies that no formatting will be applied to column 2,
' the Text (literal) format will be applied to column 9, and
' the format 'dddd dd-mmm-yyyy' will be applied to column 12.
'
' The function calls ImportThisLine, which should return
' True to import the text from the file, or False to skip
' the current line.
' This function returns the number of records imported if
' successful or -1 if an error occurred.
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Dim FINdx As Long
Dim C As Long
Dim R As Range
Dim FNum As Integer
Dim S As String
Dim RecCount As Long
Dim FieldInfos() As String
Dim FInfo() As String
Dim N As Long
Dim T As String
Dim B As Boolean

Application.EnableCancelKey = xlInterrupt
On Error GoTo EndOfFunction:

If Dir(FileName, vbNormal) = vbNullString Then
    ' file not found
    ImportFixedWidth = -1
    Exit Function
End If

If Len(FieldSpecs) < 3 Then
    ' invalid FieldSpecs
    ImportFixedWidth = -1
    Exit Function
End If

If StartCell Is Nothing Then
    ImportFixedWidth = -1
    Exit Function
End If

Set R = StartCell(1, 1)
C = R.Column
FNum = FreeFile

Open FileName For Input Access Read As #FNum
' get rid of any spaces
FieldSpecs = Replace(FieldSpecs, Space(1), vbNullString)
' omit double pipes ||
N = InStr(1, FieldSpecs, "||", vbBinaryCompare)
Do Until N = 0
    FieldSpecs = Replace(FieldSpecs, "||", "|")
    N = InStr(1, FieldSpecs, "||", vbBinaryCompare)
Loop
' omit double commas
N = InStr(1, FieldSpecs, ",,", vbBinaryCompare)
Do Until N = 0
    FieldSpecs = Replace(FieldSpecs, ",,", ",")
    N = InStr(1, FieldSpecs, ",,", vbBinaryCompare)
Loop

' get rid of leading and trailing | characters, if necessary
If StrComp(Left(FieldSpecs, 1), "|", vbBinaryCompare) = 0 Then
    FieldSpecs = Mid(FieldSpecs, 2)
End If
If StrComp(Right(FieldSpecs, 1), "|", vbBinaryCompare) = 0 Then
    FieldSpecs = Left(FieldSpecs, Len(FieldSpecs) - 1)
End If

Do
    ' read the file
    Line Input #FNum, S
    If SkipLinesBeginningWith <> vbNullString And _
            StrComp(Left(Trim(S), Len(SkipLinesBeginningWith)), _
            SkipLinesBeginningWith, vbTextCompare) Then
        If Len(S) = 0 Then
            If IgnoreBlankLines = False Then
                Set R = R(2, 1)
            Else
                ' do nothing
            End If
        Else
            ' allow code to change the FieldSpecs values

            If FieldSpecs = vbNullString Then
                ' FieldSpecs is empty. Do nothing, don't import.
            Else
                If ImportThisLine(S) = True Then
                    FieldInfos = Split(FieldSpecs, "|")
                    C = R.Column
                    For FINdx = LBound(FieldInfos) To UBound(FieldInfos)
                        FInfo = Split(FieldInfos(FINdx), ",")
                        R.EntireRow.Cells(1, C).Value = Mid(S, CLng(FInfo(0)), CLng(FInfo(1)))
                        C = C + 1
                    Next FINdx
                    RecCount = RecCount + 1
                End If
                Set R = R(2, 1)
            End If
        End If
    Else
        ' no skip first char
    End If

Loop Until EOF(FNum)

EndOfFunction:
If Err.Number = 0 Then
    ImportFixedWidth = RecCount
Else
    ImportFixedWidth = -1
End If
Close #FNum
End Function

Private Function ImportThisLine(S As String) As Boolean

Dim N As Long
Dim NoImportWords As Variant
Dim T As String
Dim L As Long

NoImportWords = Array("page", "product", "xyz")
For N = LBound(NoImportWords) To UBound(NoImportWords)
    T = NoImportWords(N)
    L = Len(T)
    If StrComp(Left(S, L), T, vbTextCompare) = 0 Then
        ImportThisLine = False
        Exit Function
    End If
Next N
ImportThisLine = True
End Function

Answer 1

这是你的＆＃34;字段定义字符串＆＃34; const {dataSource}= this.props.dataSource; const {dataSource}= this.props; ...每对的第一个数字是起始位置，第二个数字是长度...所以它应该是"1,5|2,45|3,3|4,45|5,45|6,45|7,60|8,15|9,11|10,60| _ 我没有检查过这些值，但它接近1 + 5 = 6 + 45 = 51 + 3 = 54 + 45 = 99 .....

Answer 2

在调试方面，我将使用的是尝试找出代码崩溃的。我通常写我的On Error语句，所以我可以打开和关闭错误捕获，即

而不是

 On Error GoTo EndOfFunction:

使用

 If InDebugMode then On Error Goto EndOfFunction:

InDebugMode 只是

 Public Const InDebugMode = True

这样一来，当出现问题时代码就会停止，然后你可以使用手表等来弄清楚发生了什么（见http://www.cpearson.com/excel/DebuggingVBA.aspx）

Excel和VBA在宏观中途崩溃

2 个答案: