Question

我试图在＆＃34; device＆＃34;中使用可分配的数组。驻留在GPU内存中的数据结构。代码（粘贴在下面）编译，但给出了段错误。我做错了什么吗？

模块文件名为＆＃39; gpu_modules.F90＆＃39;，如下所示：

!=============
! This module contains definitions for data structures and the data
! stored on the device
!=============

   module GPU_variables
   use cudafor

   type :: data_str_def

!=============
! single number quantities
!=============

      integer                       :: i, j 
      real(kind=8)                  :: a 

!=============
! Arrays
!=============

      real(kind=8),   allocatable   :: b(:)
      real(kind=8),   allocatable   :: c(:,:)
      real(kind=8),   allocatable   :: d(:,:,:)
      real(kind=8),   allocatable   :: e(:,:,:,:)

   end type data_str_def

!=============
! Actual data is here
!=============

   type(data_str_def), device, allocatable   :: data_str(:)

   contains

!=============
! subroutine to allocate memory
!=============

      subroutine allocate_mem(n1)
      implicit none 
      integer, intent(in)  :: n1 

      call deallocate_mem()

      write(*,*) 'works here'
      allocate(data_str(n1))

      write(*,*) 'what about allocating memory?'
      allocate(data_str(n1) % b(10))
      write(*,*) 'success!'

      return
      end subroutine allocate_mem

!=============
! subroutine to deallocate memory
!=============

      subroutine deallocate_mem()
      implicit none
      if(allocated(data_str)) deallocate(data_str)
      return 
      end subroutine deallocate_mem

   end module GPU_variables

主程序是＆＃39; gpu_test.F90＆＃39;，如下所示：

!=============
! main program 
!=============

    program gpu_test
    use gpu_variables
    implicit none

!=============
! local variables
!=============

    integer             :: i, j, n

!=============
! allocate data
!=============

    n       = 2                 ! number of data structures

    call allocate_mem(n)

!=============
! dallocate device data structures and exit
!=============

    call deallocate_mem()
    end program

编译命令（来自当前文件夹）是：

pgfortran -Mcuda=cc5x *.F90

终端输出：

$ ./a.out 
 works here
 what about allocating memory?
Segmentation fault (core dumped)

任何帮助/见解和解决方案都将受到赞赏..不，使用指针不是一个可行的选择。

编辑：可能相关的另一个细节：我使用pgfortran版本16.10

Answer 1

分段错误的原因是您必须访问主机上的data_str内存才能分配data_str（n1）％b。由于data_str在设备内存中，而不在主机内存中，因此会出现分段错误。从理论上讲，编译器可以创建一个主机temp，分配它，然后将其复制到data_str（n1）％b的描述符，但这不是今天的CUDA Fortran的一部分。

您可以通过自己创建temp来解决此问题：

      subroutine allocate_mem(n1)
      implicit none
      integer, intent(in)  :: n1
      type(data_str_def) :: data_str_h

      call deallocate_mem()

      write(*,*) 'works here'
      allocate(data_str(n1))

      write(*,*) 'what about allocating memory?'
      allocate(data_str_h% b(10))
      data_str(n1) = data_str_h
      write(*,*) 'success!'

      return
      end subroutine allocate_mem

BTW，你打算在主机内存或设备内存中分配组件b，c，d和e吗？我没有看到设备属性，所以在上面，他们会去主机内存。

Answer 2

所以我在PGI论坛上发布了这个问题，PGI的一个人确认该功能不受支持，因为我正在尝试使用它。

http://www.pgroup.com/userforum/viewtopic.php?t=5661

他的建议是使用“托管”属性或在数据结构中使用固定大小的数组。

CUDA-Fortran设备数据结构中的可分配阵列

2 个答案: