Question

[编辑澄清] 我有一个棘手的问题。我正在尝试将我们的系统推出的XML数据转换为CSV格式。我进行了搜索和搜索，如果元素不同，似乎很简单。但是，他们不是。这是我将SOAP请求发送到服务器时得到的响应：

<ArrayOfMemberInformation>
  <MemberInformation Member_Id="1" Cons_Id="234" Last_Updated="2017-02-06T09:39:57" Last_Updated_By_Cons_Id="234" Last_Updated_By_Name="Jane Doe">
    <Column Name="firstname" Value="Jane"/>
    <Column Name="lastname" Value="Doe"/>
    <Column Name="phone" Value="5551234567"/>
  </MemberInformation>
  <MemberInformation Member_Id="7" Cons_Id="789" Last_Updated="2017-03-14T18:33:03" Last_Updated_By_Cons_Id="789" Last_Updated_By_Name="Johnny Smith">
    <Column Name="firstname" Value="Johnny"/>
    <Column Name="lastname" Value="Smith"/>
    <Column Name="phone" Value="5559876543"/>
  </MemberInformation>
</ArrayOfMemberInformation>

我试图制作专栏＆＃34;名称＆＃34;列标题和值落在后续行的相应列中。这是我正在努力尝试实现这一目标的XSLT：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>
<xsl:strip-space elements="*"/>

<xsl:template match="/ArrayOfMemberInformation/MemberInformation">
<xsl:value-of select="firstname"/>,<xsl:value-of select="lastname"/>,<xsl:value-of select="phone"/>
</xsl:template>

</xsl:stylesheet>

尝试运行时得到的输出是：

,,,,

（只是逗号，没有数据）

我想要实现的输出是：

"firstname","lastname","phone"
"Jane","Doe","5551234567"
"Johnny","Smith","5559876543"

列＆＃34;名称＆＃34;是列标题，并在下面填充值。

提前感谢任何人提供的任何见解。

Answer 1

这是你可以看到它的一种方式：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>

<xsl:template match="/ArrayOfMemberInformation">
    <!-- header -->
    <xsl:text>"firstname","lastname","phone"&#10;</xsl:text>
    <!-- data rows -->
    <xsl:for-each select="MemberInformation">
        <!-- data cells -->
        <xsl:for-each select="Column">
            <xsl:text>"</xsl:text>
            <xsl:value-of select="@Value"/>
            <xsl:text>"</xsl:text>
            <xsl:if test="position()!=last()">
                <xsl:text>,</xsl:text>
            </xsl:if>
        </xsl:for-each>
        <xsl:text>&#10;</xsl:text>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

请注意，这假设每个记录具有相同的Column s，顺序相同。

如果您不想对列名进行硬编码，则可以执行以下操作：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text"/>

<xsl:template match="/ArrayOfMemberInformation">
    <!-- header -->
    <xsl:for-each select="MemberInformation[1]/Column">
        <xsl:text>"</xsl:text>
        <xsl:value-of select="@Name"/>
        <xsl:text>"</xsl:text>
        <xsl:if test="position()!=last()">
            <xsl:text>,</xsl:text>
        </xsl:if>
    </xsl:for-each>
    <xsl:text>&#10;</xsl:text>
    <!-- data rows -->
    <xsl:for-each select="MemberInformation">
        <!-- data cells -->
        <xsl:for-each select="Column">
            <xsl:text>"</xsl:text>
            <xsl:value-of select="@Value"/>
            <xsl:text>"</xsl:text>
            <xsl:if test="position()!=last()">
                <xsl:text>,</xsl:text>
            </xsl:if>
        </xsl:for-each>
        <xsl:text>&#10;</xsl:text>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

另请参阅：http://stackoverflow.com/a/25003101/3016153

使用XSLT将XML转换为CSV - 元素名称相同，属性不同

1 个答案: