Question

我制作了一个组件，在我的应用程序中使用托盘图标，当图标显示弹出菜单时，不能用Esc键关闭它。然后我找到了David Heffernan的解决方法here。我将代码集成到我的组件中，现在菜单可以用Esc关闭但是在我弹出菜单后我的应用程序完全死了，我无法访问主窗体上的任何内容，即使系统按钮也没有继续工作。

以下是重现问题的代码：

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, Menus, ShellApi;

const WM_ICONTRAY = WM_USER+1;

type
  TForm1 = class(TForm)
    PopupMenu1: TPopupMenu;
    Test1: TMenuItem;
    Test2: TMenuItem;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    IconData: TNotifyIconData;
  protected
    procedure PrivateWndProc(var Msg: TMessage); virtual;
  public
    PrivateHandle:HWND;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
begin
 PrivateHandle:=AllocateHWnd(PrivateWndProc);

 // add an icon to tray
 IconData.cbSize:=SizeOf(IconData);
 IconData.Wnd:=PrivateHandle;
 IconData.uID:=1;
 IconData.uFlags:=NIF_MESSAGE + NIF_ICON;
 IconData.uCallbackMessage:=WM_ICONTRAY;
 IconData.hIcon:=Application.Icon.Handle;
 Shell_NotifyIcon(NIM_ADD, @IconData);
end;

procedure TForm1.FormDestroy(Sender: TObject);
begin
 IconData.uFlags:=0;
 Shell_NotifyIcon(NIM_DELETE, @IconData);
 DeallocateHWnd(PrivateHandle);
end;

procedure TForm1.PrivateWndProc(var Msg: TMessage);
var p:TPoint;
begin
 if (Msg.Msg = WM_ICONTRAY) and (Msg.LParam=WM_RBUTTONUP) then
  begin
   GetCursorPos(p);
   SetForegroundWindow(PrivateHandle);
   PopupMenu1.Popup(p.x,p.y);
   PostMessage(PrivateHandle, WM_NULL, 0, 0);
  end;
end;

end.

Answer 1

我猜你刚才错过了致电DefWindowProc。试试这个：

procedure TForm1.PrivateWndProc(var Msg: TMessage);
begin
  if (Msg.Msg = WM_ICONTRAY) and (Msg.lParam = WM_RBUTTONUP) then
  begin
    ...
  end
  else
    Msg.Result := DefWindowProc(PrivateHandle, Msg.Msg, Msg.wParam, Msg.lParam);
end;

为什么使用Esc关闭弹出菜单的着名解决方法是不能使用私有句柄？

1 个答案: