Question

我试图将基于cmake的项目包含在库vlc-qt中，作为github存储库的外部项目。

该项目采用推荐方式：

FIND_PACKAGE(VLCQt REQUIRED COMPONENTS Widgets)

cmake在配置阶段执行此命令，因此您可以看到该库未在此时构建。

什么是避免这种情况的正确方法？

Answer 1

将您自己的项目和VLCQt项目放入具有ExternalProject_Add的外部项目中，并创建一个顶级CMakeLists.txt文件，以便逐个构建它们。

您的目录结构如下所示：

ProjectRoot/
|-- CMakeLists.txt
|-- MyProject/
|   |-- sources/
|   `-- CMakeLists.txt
`-- modules/
    |-- MyProject.cmake
    `-- ExternalVLCQt.cmake

ProjectRoot/modules/ExternalVLCQt.cmake可能如下所示：

set(VLCQT_ROOT ${EXT_INSTALL_PATH}/vlcqt CACHE INTERNAL "")

ExternalProject_Add(vlcqt
    URL "http://url.of.source/release.0.1.tar.gz"
    CMAKE_ARGS -DCMAKE_INSTALL_PREFIX=${VLCQT_ROOT}
    INSTALL_COMMAND make install
)

list(APPEND GLOBAL_THIRDPARTY_LIB_ARGS "-DVLCQT_ROOT:PATH=${VLCQT_ROOT}")

ProjectRoot/modules/MyProject.cmake可能如下所示：

ExternalProject_Add(my_project
    DEPENDS vlcqt
    SOURCE_DIR ${CMAKE_SOURCE_DIR}/MyProject
    CMAKE_ARGS
        ${GLOBAL_THIRDPARTY_LIB_ARGS}
        -DCMAKE_INSTALL_PREFIX=${EXT_INSTALL_PATH}/my_project
    BUILD_COMMAND make
)

然后最后ProjectRoot/CMakeLists.txt应该包含以下内容：

cmake_minimum_required(VERSION 3.1.0 FATAL_ERROR)
project(MyProject VERSION 0.1)

set(CMAKE_MODULE_PATH
    "${CMAKE_CURRENT_SOURCE_DIR}/modules"
    ${CMAKE_MODULE_PATH}
)

include(ExternalProject)

set_directory_properties(PROPERTIES EP_BASE ${CMAKE_BINARY_DIR}/ExtProjects)
get_directory_property(EXT_BASE_PATH EP_BASE)

set(EXT_INSTALL_PATH ${EXT_BASE_PATH}/Install)

include(ExternalVLCQt)
include(MyProject)

install(DIRECTORY ${EXT_INSTALL_PATH}/my_project DESTINATION .)

您可以阅读有关此模式的更多信息here。通过此模式，ProjectRoot/MyProject/CMakeLists.txt将在CMakeLists.txt构建后的顶级vlcqt的构建时配置。因此，find_package会找到VLCQt包。

注意：在我的示例中，使用VLCQT_ROOT命令的CMakeLists.txt MyProject将收到find_package。此变量是find_package命令的提示，对于不同的包，这可能会有所不同。 find_package使用的每个CMake模块都有自己的可变要求。

如何仅在构建阶段执行cmake :: find_package

1 个答案: