Question

我想在标识符周围包含一个getter和setter函数，以便

(define x 1)
(set! x v) ; should expand to (custom-set! x v)
x          ; should expand to (custom-get x)

其中 custom-put！和 custom-get 在其他地方定义并添加其他行为，例如记录。

在racket guide（第16.1.6节）中，有一个Set！-Transformer的例子，它适用于setter和一个零参数的getter。但是，我需要一个宏，它将标识符出现扩展到getter函数，并将匹配的标识符作为其参数。

我尝试在链接部分中采用宏，如下所示：

(define-syntax-rule (generate-accessors id get put!)
(define-syntax id
  (make-set!-transformer
   (lambda (stx)
       (syntax-case stx (set! get)
         [id (identifier? (syntax id)) (syntax (get id))]
         [(set! id e) (syntax (put! id e))])))))

问题是（syntax（get id））会导致无限扩展。是否有一种直接的方法来切断模板表达式的递归？我还考虑过生成一个绑定到 id 的新标识符并将其包含在文字列表中，但我不知道如何完成此操作。

Answer 1

您链接的示例使用上一节中的代码定义get-val和put-val!：

(define-values (get-val put-val!)
  (let ([private-val 0])
    (values (lambda () private-val)
            (lambda (v) (set! private-val v)))))

(define-syntax val
  (make-set!-transformer
   (lambda (stx)
     (syntax-case stx (set!)
       [val (identifier? (syntax val)) (syntax (get-val))]
       [(set! val e) (syntax (put-val! e))]))))

val ;; 0
(set! val 42)
val ;; 42

让我们写一下宏写作宏generate-accessors 参数化标识符和访问器，并看它是否有效：

(define-syntax (generate-accessors stx)
  (syntax-case stx ()
    [(_ val get-val put-val!)
     (syntax
      (define-syntax val
        (make-set!-transformer
         (lambda (stx)
           (syntax-case stx (set!)
             [val (identifier? (syntax val)) (syntax (get-val))]
             [(set! val e) (syntax (put-val! e))])))))]))

(generate-accessors foo get-val put-val!)
foo ;; 0
(set! foo 42)
foo ;; 42

另外，让我们用另一对访问器来练习它，它显示了一个副作用＆＃34;伐木＆＃34;：

(define-values (custom-get custom-set!)
  (let ([private-val 0])
    (values (lambda () (println "get") private-val)
            (lambda (v) (println "set") (set! private-val v)))))

(generate-accessors bar custom-get custom-set!)
bar ;; 0
(set! bar 42)
bar ;; 42

编辑：在回复您的评论时，这是一种变体，它为每次调用生成一对新的访问者（和值）。它允许您提供一对要调用的运行时函数，以执行额外的工作（此处只是println）。（您可以简化此操作以硬编码println或log-debug或其他任何内容，如果您发现它总是相同的话。）

(require (for-syntax racket/base
                     racket/syntax
                     syntax/parse))

(define-syntax (define/logged stx)
  (syntax-parse stx
    [(_ id:id init:expr on-get:expr on-set:expr)
     #:with get (format-id stx "get-~a" #'id)
     #:with set (format-id stx "set!-~a" #'id)
     #'(begin
         (define-values (get set)
           (let ([v init])
             (values (λ () (on-get 'id v) v)
                     (λ (e) (on-set 'id e) (set! v e)))))
         (define-syntax id
           (make-set!-transformer
            (λ (stx)
              (syntax-parse stx
                [id:id #'(get)]
                [(set! id e) #'(set e)])))))]))

(define (on-get id v)
  (println `(get ,id ,v)))

(define (on-set! id v)
  (println `(set! ,id ,v)))

(define/logged foo 0 on-get on-set!)
foo
(set! foo 42)
foo

;; prints:
;; '(get foo 0)
;; 0
;; '(set! foo 42)
;; '(get foo 42)
;; 42

我并不是100％明确你正在尝试做的事情。也许这更接近，或者至少给你一些想法。

请注意，我切换到syntax-parse，而不是尝试按照指南中的原始示例进行操作。只是因为。

用于包围标识符的吸气功能的球拍宏

1 个答案: