Question

我有XML文件。我想复制它并删除这些属性：CT_ARCH_CPU，ExpandedColumnCount。我该怎么办？

ExpandedRowCount

如果我使用此XSLT文件，则删除元素<Table ss:ExpandedColumnCount="7" ss:ExpandedRowCount="3" x:FullColumns="1" x:FullRows="1" ss:DefaultRowHeight="15"> <Row ss:AutoFitHeight="0"/> <Row ss:Index="3" ss:AutoFitHeight="0"> <Cell ss:Index="4"><Data ss:Type="String">c1</Data></Cell> <Cell><Data ss:Type="String">c2</Data></Cell> <Cell><Data ss:Type="String">c3</Data></Cell> <Cell><Data ss:Type="String">c4</Data></Cell> </Row> </Table>。

Table

我想要的是什么：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="Table|@ExpandedColumnCount"/>
</xsl:stylesheet>

我做错了什么？

Answer 1

替换

<xsl:template match="Table|@ExpandedColumnCount"/>

与

<xsl:template match="@ss:ExpandedColumnCount|@ss:ExpandedRowCount"/>

在XML中定义名称空间前缀

<Table xmlns:ss="http://example.com/ss"
       xmlns:x="http://example.com/x"
       ss:ExpandedColumnCount="7" ss:ExpandedRowCount="3" x:FullColumns="1"
       x:FullRows="1" ss:DefaultRowHeight="15">
  <Row ss:AutoFitHeight="0"/>
  <Row ss:Index="3" ss:AutoFitHeight="0">
    <Cell ss:Index="4"><Data ss:Type="String">c1</Data></Cell>
    <Cell><Data ss:Type="String">c2</Data></Cell>
    <Cell><Data ss:Type="String">c3</Data></Cell>
    <Cell><Data ss:Type="String">c4</Data></Cell>
  </Row>
</Table>

并在您的XSLT中

<xsl:stylesheet version="1.0" 
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:ss="http://example.com/ss">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="@ss:ExpandedColumnCount|@ss:ExpandedRowCount"/>
</xsl:stylesheet>

然后，您将获得所需的结果：

<?xml version="1.0" encoding="UTF-8"?>
<Table xmlns:ss="http://example.com/ss"
       xmlns:x="http://example.com/x"
       x:FullColumns="1"
       x:FullRows="1"
       ss:DefaultRowHeight="15">
   <Row ss:AutoFitHeight="0"/>
   <Row ss:Index="3" ss:AutoFitHeight="0">
      <Cell ss:Index="4">
         <Data ss:Type="String">c1</Data>
      </Cell>
      <Cell>
         <Data ss:Type="String">c2</Data>
      </Cell>
      <Cell>
         <Data ss:Type="String">c3</Data>
      </Cell>
      <Cell>
         <Data ss:Type="String">c4</Data>
      </Cell>
   </Row>
</Table>

在评论中更新每个问题：XSLT会破坏名称空间（ 不推荐 ）以删除目标属性：

<xsl:stylesheet version="1.0" 
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:ss="http://example.com/ss">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:template match="node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="@*">
    <xsl:if test="local-name()!='ExpandedColumnCount' and
                  local-name()!='ExpandedRowCount'">
      <xsl:copy/>
    </xsl:if>
  </xsl:template>
</xsl:stylesheet>

如何使用XSLT从XML中的元素中删除不必要的属性？

1 个答案: