Question

我正在使用KRL通过他们的API向谷歌发送请求，这是我从他们那里得到的字面回复：

handleResponse({ "data": { "responses": [ { "response": "successful" } ] } } );

你如何建议我通过选择处理这个，因为它不是'有效的'JSON语法？它包含有效的JSON语法，但整体上无效。谢谢你的帮助。

Answer 1

更新：查看Google翻译API后，看起来JSONP回调参数是可选的。不要指定回调，您将不再遇到此问题。：）

http://code.google.com/apis/language/translate/v2/using_rest.html#WorkingResults

更好的选择：

如果可以，请在对谷歌API的调用中指定没有回调功能。如果您只需要使用普通JSON而不是JSONP，则可以使用pick运算符。

不是更好的选择：

如果API仅返回JSONP，那么您可以执行正则表达式替换以从JSON中删除填充，然后允许您使用pick运算符。

你需要什么：

使用beesting或encode function
Replace function
Decode function
Pick operator

完整的应用示例：

ruleset a60x494 {
  meta {
    name "jsonp-to-json-test"
    description <<
      jsonp-to-json-test
    >>
    author "Mike Grace"
    logging on
  }

  global {
    returnedJsonpAsString = 'handleResponse({ "data": { "responses": [ { "response": "successful" } ] } } );';
    datasource googleApi <- "blah blah blah";
  }

  rule fix_jsonp_to_json {
    select when pageview ".*"
    pre {
      cleanJson = returnedJsonpAsString.replace(re/^.*\((.*)\);/,"$1");
      response = cleanJson.decode().pick("$..response");
    }
    {
      notify("Response",response) with sticky = true;
      emit <|
        console.log(returnedJsonp);
        console.log(cleanJson);
      |>;
    }
  }
}

处理KRL的响应

1 个答案: