Question

想象一下，我们有这样的东西（这只是一个例子）

public interface Foo : GLib.Object {
    public abstract double *f();
}

public class Toto : GLib.Object, Foo {

    private double i;

    public Toto(double i = 0) {
        this.i = i;
    }

    public double *f() {
        return &i;
    }

    public static int main(string[] args) {
        Foo a = new Toto(42.0);
        double i = *a.f();
        stdout.printf("%.3f\n", i);
        return 0;
    }
}

此代码完全正常，但问题是Foo必须与public abstract T *f()一致，因此Toto必须实现Foo<double>，但

`double'不是受支持的泛型类型参数

（我的第一个问题是“为什么？”，据我所知，我可以使用int，例如没有任何问题）

所以它是Foo<double?>，我需要类似double i = (!) *(a.f())的东西，但它只是不起作用（在C级别）

错误：无效使用void表达式i = (gdouble) (*(*_tmp1_));

那么如何使用f()方法？

（我的vala版本是0.36.3）

Answer 1

为什么你首先在Vala中使用指针？（不鼓励，指针是角落案例的语言。）

Vala中的可空类型是生成的C代码中的指针。

因此解决这个问题的一种方法是：

public interface Foo<T> : GLib.Object {
    public abstract T f();
}

public class Toto : GLib.Object, Foo<double?> {

    private double i;

    public Toto(double i = 0) {
        this.i = i;
    }

    public double? f() {
        return i;
    }

    public static int main(string[] args) {
        Foo<double?> a = new Toto(42.0);
        double? i = a.f();
        stdout.printf("%.3f\n", (!) i);
        return 0;
    }
}

这里使用valac 0.36.3编译并完美地工作。

Toto.f生成的C函数的类型签名是：

static gdouble* toto_real_f (Foo* base);

可空指针作为Vala中的返回值

1 个答案: