Question

在系统菜单（标题栏的左侧）中，我可以添加自己的菜单项。我也可以删除例如DeleteMenu(SysMenu, SC_MINIMIZE, MF_BYCOMMAND) ;

但是，如果删除标准的[恢复，最小化，最大化，大小，关闭]，其功能将丢失（即最大化按钮不再有效）

有没有办法隐藏这些菜单项或将它们从系统菜单的第一级移开？ a）使它们不可见 b）移动到子菜单 c）删除但仍然获取按钮消息

Answer 1

a）让它们不可见

API没有隐藏/隐藏菜单项的概念。

b）转到子菜单

您可以在不影响功能的情况下将项目移动（或更确切地删除和添加）到子菜单。

E.g。将“最小化”移动到子菜单：

var
  SysMenu, SubMenu: HMENU;
  StrMin: string;
  StrMinLen: Integer;
begin
  SysMenu := GetSystemMenu(Handle, False);
  StrMinLen := GetMenuString(SysMenu, SC_MINIMIZE, nil, 0, MF_BYCOMMAND);
  if StrMinLen > 0 then begin
    Inc(StrMinLen);
    SetLength(StrMin, StrMinLen);
    GetMenuString(SysMenu, SC_MINIMIZE, PChar(StrMin), StrMinLen, MF_BYCOMMAND);
    SubMenu := CreateMenu;
    if SubMenu <> 0 then begin
      DeleteMenu(SysMenu, SC_MINIMIZE, MF_BYCOMMAND);
      AppendMenu(SubMenu, MF_STRING, SC_MINIMIZE, PChar(StrMin));
      InsertMenu(SysMenu, 0, MF_BYPOSITION or MF_POPUP, SubMenu, 'Minimize->');
      InsertMenu(SysMenu, 1, MF_BYPOSITION or MF_SEPARATOR, 0, nil);
    end;
  end;

在恢复系统菜单之前销毁子菜单：

var
  Info: TMenuItemInfo;
begin
  Info.cbSize := SizeOf(Info);
  Info.fMask := MIIM_SUBMENU;
  if GetMenuItemInfo(GetSystemMenu(Handle, False), 0, True, Info) then
    DestroyMenu(Info.hSubMenu);
  GetSystemMenu(Handle, True);

c）删除但仍然获取按钮消息

如果删除f.i.，“最小化”项，系统不会向窗口发送最小化命令的WM_SYSCOMMAND消息。所以没有任何命令可以回应。

你仍然可以收听按钮信息，f.i。向左按下按钮。但按钮点击/向上消息与按钮点击实际上并不相同。按钮单击包含三个操作，鼠标按下，捕获并再次按下按钮。无论如何你想要这样做的例子可以是：

procedure TForm1.WMNCLButtonDown(var Message: TWMNCLButtonDown);
begin
  inherited;
  if (Message.HitTest = HTMINBUTTON) and not IsIconic(Handle) then
    ShowWindow(Handle, SW_MINIMIZE);
end;

Answer 2

History：

最初，窗口标题右上角只有两个按钮，最小化和最大化按钮，它们是用窗口样式控制的。 Windows 95添加了“关闭”按钮，但随后出现了解何时启用和禁用它的问题。但是等等，我们已经知道何时启用和禁用它：应用程序在启用和禁用SC_CLOSE菜单项时告诉我们。 Bingo，只需将Close按钮连接到现有的菜单项（哪些应用程序已经习惯了维护），以及魔术，它只是起作用。无需应用程序编写特殊代码即可支持“关闭”按钮。

现在您知道为什么SC_CLOSE与按钮绑定了。因此，在某些操作期间阻止用户关闭的正确方法是禁用菜单项。

如果您因任何原因坚持删除它但仍然允许关闭窗口，则必须在系统菜单即将显示（WM_INITMENU）和revert时删除该项目菜单关闭后的系统菜单（WM_UNINITMENUPOPUP）。

Answer 3

Sertac回答了这个问题：你只能移动它们。

以下是使Sysmenu有用的完整最终解决方案，其中包括： a）移动除子菜单附近的所有标准项目，子菜单隐藏在分隔符后面。 b）将Form1.PopupMenu1中的菜单项添加到SysMenu c）删除它们（在使窗口全屏/无边框之前，因为这会破坏系统菜单） d）显示sysmenu

procedure TForm1.SysMenuAddRemoveExtraItems(Add:boolean=true);
//
    var
      SysMenu, SubMenu : HMenu;
      const NumItems:integer=0;

    procedure InsertM(Position,I:integer;J:integer=-1;S:string='');
    // https://msdn.microsoft.com/en-us/library/windows/desktop/ms647987(v=vs.85).aspx
      var M:TMenuItem; H:thandle; Flags:cardinal;
    begin
      M:=PopupMenu1.Items;
      if I>=0 then M:=M.Items[I];
      Flags:=MF_BYPOSITION+MF_STRING;
      if M.Count>1 then Flags:=Flags+MF_POPUP;

      if J>=0 then M:=M.Items[J];
      H:=M.Handle;
      if S='' then S:=M.Caption;
      InsertMenu(SysMenu,Position,Flags,H,pwidechar(S));
      inc(NumItems);
    end;
    procedure InsertSeparator(Position:integer);
    begin
      InsertMenu(SysMenu,Position,MF_BYPOSITION,MF_SEPARATOR,0); {Add a seperator bar to main form-form1}
      inc(NumItems);
    end;
    procedure RemoveItems;
    var i:integer;
    begin
      for i := 1 to NumItems do  //remove items from top
        RemoveMenu(SysMenu,0,MF_BYPOSITION);
      NumItems:=0;
    end;

    procedure DeleteAppend(ID:cardinal); //to move standard menuitems to submenu
    var
      Caption: string;
      CaptionLen: Integer;
    begin
    CaptionLen := GetMenuString(SysMenu, ID, nil, 0, MF_BYCOMMAND);
    if CaptionLen > 0 then begin
      Inc(CaptionLen);
      SetLength(Caption, CaptionLen);
      GetMenuString(SysMenu, ID, PChar(Caption), CaptionLen, MF_BYCOMMAND);

      DeleteMenu(SysMenu, ID, MF_BYCOMMAND);
      AppendMenu(SubMenu, MF_STRING, ID, PChar(Caption));
      end;
    end;
    procedure MoveDefaultSysMenuItemsToSubmenu(Caption:string='';JustSeparator:boolean=false);
    //Can either have a a caption or JustSeparator (submenu will be inaccessible)
    // https://stackoverflow.com/questions/44735708/system-menu-how-to-hide-move-standard-menuitems/44743027#44743027
    begin
    SubMenu := CreateMenu; //make submenu to move them into
      if SubMenu <> 0 then begin
        DeleteAppend(SC_RESTORE);
        DeleteAppend(SC_MOVE);
        DeleteAppend(SC_SIZE);
        DeleteAppend(SC_MINIMIZE);
        DeleteAppend(SC_MAXIMIZE);
        if JustSeparator then begin
            DeleteMenu(SysMenu, 0, MF_BYPOSITION); //remove separator above CLOSE
            InsertMenu(SysMenu, 0, MF_BYPOSITION or MF_POPUP or MF_SEPARATOR, SubMenu, '');
          end else begin
            DeleteMenu(SysMenu, 0, MF_BYPOSITION); //remove separator above CLOSE
            InsertMenu(SysMenu, 0, MF_BYPOSITION or MF_POPUP, SubMenu, PChar(Caption));
            InsertMenu(SysMenu, 1, MF_BYPOSITION or MF_SEPARATOR, 0, nil);
        end;
      end;
    end;
    procedure DestroySubmenu;
      var Info: TMenuItemInfo;
    begin
      Info.cbSize := SizeOf(Info);
      Info.fMask := MIIM_SUBMENU;
      if GetMenuItemInfo(GetSystemMenu(Handle, False), 0, True, Info) then
        DestroyMenu(Info.hSubMenu);
      //GetSystemMenu(Handle, True);
    end;

begin
  SysMenu := GetSystemMenu(Handle, FALSE) ;   {Get system menu}
  //InsertMenu(SysMenu,1,MF_BYPOSITION+MF_STRING,SC_MyMenuItem2,'pqr');
  if Add then begin
    MoveDefaultSysMenuItemsToSubmenu('',true);
 //   InsertSeparator(0);
    InsertM(0,PopupMenu1.Items.Count-2);
    InsertM(0,-1,-1,'Menu'); //help
    InsertM(0,7);
    end
  else begin  //remove items
    RemoveItems;
    DestroySubmenu;
  end;
end;

//------------------------------------    
procedure TForm1.ShowSysMenu;
var P:TPoint;
begin
  P:=ClientToScreen(Point(0,0));
  TrackPopupMenu(GetSystemMenu(Handle, FALSE), TPM_LEFTALIGN+TPM_TOPALIGN+TPM_RETURNCMD+TPM_NONOTIFY,
                 P.X,P.Y,0,self.Handle,nil);
end;

//--------------------------------------------------------------

procedure TForm1.WMSysCommand(var Msg: TWMSysCommand);
//  https://www.delphipower.xyz/guide_7/customizing_the_system_menu.html
var Item: TMenuItem;
begin

Item := PopupMenu1.FindItem (Msg.CmdType, fkCommand);
if assigned(Item) then Item.Click
else
//  case Msg.CmdType of
//    //put any other specials in here
//  else
   inherited;
//  end;
end;

系统菜单：如何隐藏/移动标准菜单项

3 个答案: