Question

我需要查找数字（重复出现）并返回数字旁边的单元格值，但仅限于同一日期。结果必须连接到同一个目标细胞中。

我在Mac上使用Excel 2011。我没有Textjoin功能。但是，我找到了一个VBA UDF来查找并将多个值返回到一个单元格中。这就是我正在使用的：

Function MYVLOOKUP(pValue As String, pWorkRng As Range, pIndex As Long)
'Update 20150310
Dim rng As Range
Dim xResult As String
xResult = ""
For Each rng In pWorkRng
    If rng = pValue Then
        xResult = xResult & " " & rng.Offset(0, pIndex - 1)
    End If
Next
MYVLOOKUP = xResult
End Function

它有点工作，但只是在一个单元格中查找值并在另一列中找到它。问题是我正在查找的值在不同的日期重复，我只想返回给定日期的值。我附上了一份我在下面尝试做的样本：

Sample Spreadsheet

注意“所需数据格式”G2正在为数据库中的两个日期返回Employee 1001的数据，但我只希望它返回相关日期的数据，所以我尝试在myvlookup UDF中设置第一个变量到“E2：F2”，以便该函数同时查找Date和Employee＃，但该函数似乎不起作用。

应在G2中显示的值为“80011,80025”，应在G3中显示的值为“80011,80030”等。

我希望我有更多时间自己解决这个问题，但时间非常重要，所以我需要帮助。

Answer 1

这是一个模仿TEXTJOIN（）的UDF：

Function TEXTJOIN(delim As String, skipblank As Boolean, arr)
    Dim d As Long
    Dim c As Long
    Dim arr2()
    Dim t As Long, y As Long
    t = -1
    y = -1
    If TypeName(arr) = "Range" Then
        arr2 = arr.Value
    Else
        arr2 = arr
    End If
    On Error Resume Next
    t = UBound(arr2, 2)
    y = UBound(arr2, 1)
    On Error GoTo 0

    If t >= 0 And y >= 0 Then
        For c = LBound(arr2, 1) To UBound(arr2, 1)
            For d = LBound(arr2, 1) To UBound(arr2, 2)
                If arr2(c, d) <> "" Or Not skipblank Then
                    TEXTJOIN = TEXTJOIN & arr2(c, d) & delim
                End If
            Next d
        Next c
    Else
        For c = LBound(arr2) To UBound(arr2)
            If arr2(c) <> "" Or Not skipblank Then
                TEXTJOIN = TEXTJOIN & arr2(c) & delim
            End If
        Next c
    End If
    TEXTJOIN = Left(TEXTJOIN, Len(TEXTJOIN) - Len(delim))
End Function

使用数据，您可以在数组公式中使用它：

=TEXTJOIN(" ",TRUE,IF((F2=B$2:B$14)*(A$2:A$14=E2),C$2:C$14,""))

作为数组公式，需要在退出编辑模式时使用Ctrl-Shift-Enter而不是Enter确认。如果操作正确，那么Excel会将{}放在公式周围。

Excel2011 - 按日期

1 个答案: