Question

我正在编写的转换必须从给定的节点集组成一个逗号分隔的字符串值。必须根据输入值中第一个字符的随机（非字母）映射对结果字符串进行排序。

我想出了这个：

<?xml version="1.0" encoding="utf-8"?>    
<xsl:stylesheet    
       version="1.0"    
       xmlns:xsl="http://www.w3.org/1999/XSL/Transform"    
       xmlns:tmp="http://tempuri.org"    
       exclude-result-prefixes="tmp"    
>    
       <xsl:output method="xml" indent="yes"/>

       <tmp:sorting-criterion>    
             <code value="A">5</code>    
             <code value="B">1</code>    
             <code value="C">3</code>    
       </tmp:sorting-criterion>

       <xsl:template match="/InputValueParentNode">    
             <xsl:element name="OutputValues">    
             <xsl:for-each select="InputValue">    
                    <xsl:sort select="document('')/*/tmp:sorting-criterion/code[@value=substring(.,1,1)]" data-type="number"/>    
                    <xsl:value-of select="normalize-space(.)"/>   
                    <xsl:if test="position() != last()">    
                           <xsl:text>,</xsl:text>    
                    </xsl:if>
             </xsl:for-each>    
             </xsl:element>    
       </xsl:template>    
</xsl:stylesheet>

它不起作用，看起来XPath document('')/*/tmp:sorting-criterion/code[@value=substring(.,1,1)]没有像我期望的那样进行评估。我已经检查过用substring(.,1,1)替换文字，它会评估为正确的值。

那么，我是否遗漏了一些使得排序XPath表达式不能按照我的预期进行评估的东西，或者只是以这种方式进行评估是不是很难？

如果无法创建有效的XPath表达式，是否有解决方法可以实现我的目的？

注意：我受限于XSLT-1.0

示例输入：

<?xml version="1.0" encoding="utf-8"?>
<InputValueParentNode>
       <InputValue>A input value</InputValue>
       <InputValue>B input value</InputValue>
       <InputValue>C input value</InputValue>
</InputValueParentNode>

预期的输出：

<?xml version="1.0" encoding="utf-8"?>
<OutputValues>B input value,C input value,A input value</OutputValues>

Answer 1

将self::node()缩写.替换为current()函数。

更好的谓词是：starts-with(normalize-space(current()),@value)

Answer 2

除了根据Alejandro´s answer,更改转换之外，我发现最好使用XSL变量来映射数据，以避免声明虚拟命名空间（tmp），如Dimitre´s answer to another related question中所示。

我的最终实施：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet
       version="1.0"
       xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
> 
       <xsl:output method="xml" indent="yes"/>

       <xsl:template match="/InputValueParentNode">
             <xsl:variable name="sorting-map">
                    <i code="A" priority="5"/>
                    <i code="B" priority="1"/>
                    <i code="C" priority="3"/>
             </xsl:variable>
             <xsl:variable name="sorting-criterion" select="document('')//xsl:variable[@name='sorting-map']/*"/>

             <xsl:element name="OutputValues">
             <xsl:for-each select="InputValue">
                    <xsl:sort select="$sorting-criterion[@code=substring(normalize-space(current()),1,1)]/@priority" data-type="number"/>
                    <xsl:value-of select="normalize-space(current())"/>
                    <xsl:if test="position() != last()">
                           <xsl:text>,</xsl:text>
                    </xsl:if>
             </xsl:for-each>
             </xsl:element>
       </xsl:template>
</xsl:stylesheet>

使用字段子字符串进行XSL关联排序

2 个答案: