Question

我有一个解析的对象看起来有点像这样：

{
  "data":
  [
    {
      "virtio0": "some text",
      "virtio1": "blah",
      "ide2": "some other text",
      "cores": 1,
      "mem": 512,
      ...
    },
    {
      // The same ...
    }
  ]
}

现在我基本上想把它解析成[VM]，但我的问题是那些编号的字段。根据VM配置，它可能有也可能没有virtioX字段，ideX字段..我没有提前知道一种方法，也没有猜测数字。我认为最好的方法是定义一个包含类似Virtio |的磁盘类型萨塔|类型的IDE等等，以及值的Text字段，然后每个VM都有一个[Disk]类型。像这样：

data DiskType = Virtio | Sata | IDE
data Disk     = Disk {diskType :: DiskType, diskPath :: Text}
data VM       = VM {cores :: Int, disks :: [Disk], mem :: Int, ...}

那会很棒，但是如何将我直接在VM json对象中的随机字段解析成列表呢？

Answer 1

虽然我不认为自己是Haskell专家，甚至不认为是Aeson专家，但我认为我发现了一些有用的东西。把它当成它。

以下代码都使用了此模块声明和这些导入：

{-# LANGUAGE OverloadedStrings #-}
module Main where

import Control.Applicative ((<$>), (<|>))
import Data.Aeson
import Data.ByteString.Lazy (ByteString)
import Data.HashMap.Lazy (HashMap, foldlWithKey')
import Data.Foldable (toList)
import Data.Text (Text, stripPrefix, unpack)
import Text.Read (readMaybe)

我稍微更改了类型声明：

data DiskType = Virtio | Sata | IDE deriving (Show)
data Disk =
  Disk { diskType :: DiskType, diskNumber :: Int, diskPath :: Text }
  deriving (Show)
data VM = VM { cores :: Int, disks :: [Disk], mem :: Int } deriving (Show)

最显着的区别是我将diskNumber添加到Disk类型，以便它可以捕获磁盘类型后的数字以及与磁盘属性关联的文本。 / p>

另一个变化是我将所有类型都设为Show的实例。这只是为了能够测试我的代码是否有效。

首先，我定义了一个小辅助函数，可以在给定前缀后找到数字：

findNumber :: Read a => Text -> Text -> Maybe a
findNumber prefix candidate =
  stripPrefix prefix candidate >>= (readMaybe . unpack)

示例：

*Main Data.Text> findNumber (pack "ide") (pack "ide2") :: Maybe Int
Just 2
*Main Data.Text> findNumber (pack "sata") (pack "sata0") :: Maybe Int
Just 0
*Main Data.Text> findNumber (pack "foo") (pack "bar") :: Maybe Int
Nothing

这使我能够编写一个函数来查找Object中的所有磁盘：

findDisks :: HashMap Text Value -> [Disk]
findDisks = foldlWithKey' folder []
  where
    findVirtio k s = flip (Disk Virtio) s <$> findNumber "virtio" k
    findSata   k s = flip (Disk Sata)   s <$> findNumber "sata"   k
    findIde    k s = flip (Disk IDE)    s <$> findNumber "ide"    k
    folder acc k (String s) =
      acc ++ toList (findVirtio k s <|> findSata k s <|> findIde k s)
    folder acc _ _ = acc

Object是HashMap Text Value的类型别名，因此此函数将Object作为输入，并返回它可以找到的Disk值的列表。< / p>

这足以为FromJSON定义VM的实例：

instance FromJSON VM where
  parseJSON = withObject "VM" $ \o -> do
    let disks = findDisks o
    cores <- o .: "cores"
    mem   <- o .: "mem"
    return $ VM cores disks mem

为了测试这是否有效，我创建了这个JSON字符串：

myJson :: ByteString
myJson =
  "[\
    \{\
      \\"virtio0\": \"some text\",\
      \\"virtio1\": \"blah\",\
      \\"ide2\": \"some other text\",\
      \\"cores\": 1,\
      \\"mem\": 512\
    \}\
  \]"

并使用main：

main :: IO ()
main = do
  let vms = decode myJson :: Maybe [VM]
  print vms

执行时，它会输出解码值：

Just [VM {cores = 1, disks = [Disk {diskType = IDE, diskNumber = 2, diskPath = "some other text"},Disk {diskType = Virtio, diskNumber = 1, diskPath = "blah"},Disk {diskType = Virtio, diskNumber = 0, diskPath = "some text"}], mem = 512}]

请注意，此处解析的JSON只是一个VM对象数组。我没有包含具有data属性的外部容器对象，但如果您需要帮助，我认为这应该是一个单独的问题：）

Answer 2

如果你说只有9个virtio和2个ide，一个简单的，也许不那么优雅的方法是使用Data.Foldable中的asum函数（这是各种解析库的通用选择）

$query = "SELECT id,latitude, longitude, SQRT(POW(69.1 * (latitude - '".$lat."' ), 2) +  POW(69.1  ('".$lon."'  - longitude)  COS(latitude / 57.3), 2)) AS distance FROM business_signup_details where event_type like '%3,4%' and business_details_approved = '1' HAVING distance < $distance ORDER BY distance";

我还没有尝试过代码。有关进一步参考，请参阅此link以获取有关使用Aeson库进行haskell JSON解析的综合指南。

FromJSON从多个字段中创建一个列表

2 个答案: