Question

使用此表：

CREATE TABLE HR.MSG_USER ( 
ID                   number(38)  NOT NULL,
NAME                 varchar2(100)  NOT NULL,
PASS                 varchar2(10)  NOT NULL,
LOGIN                varchar2(20)  NOT NULL,
CONSTRAINT IDX_USER_LOGIN_UNIQUE UNIQUE ( LOGIN ) ,
CONSTRAINT PK_USER PRIMARY KEY ( ID ) ,
CONSTRAINT IDX_USER_NAME_UNIQUE UNIQUE ( NAME ) 
);

我创建了这个程序：

create or replace procedure new_user ( login IN VARCHAR, name IN VARCHAR, pass IN VARCHAR) is

rowsFound number;
ERR_NULL            exception;
ERR_NAME_TOO_LONG   exception;
ERR_NAME_DUPLICATED exception;
ERR_UNIQUE          exception;

PRAGMA EXCEPTION_INIT(ERR_NULL,            -20001);
PRAGMA EXCEPTION_INIT(ERR_NAME_TOO_LONG,   -20002);
PRAGMA EXCEPTION_INIT(ERR_NAME_DUPLICATED, -20003);
PRAGMA EXCEPTION_INIT(ERR_UNIQUE,          -20013);

begin

  if (login is null) or (name is null) or (pass is null) then
    raise_application_error(-20001, 'Datos de Usuario Nulos');
  end if; 

  if (LENGTH(name) > 100) then
    raise_application_error(-20002, 'Nombre Usuario Demasiado Largo');
  end if; 

  select count(*) into rowsFound from MSG_USER where NAME = name;
  if rowsFound >= 1 then
        raise_application_error(-20013, 'Usuario Ya Existe: Name');
  end if;

  select count(*) into rowsFound from MSG_USER where LOGIN = login;
  if rowsFound >= 1 then
        raise_application_error(-20013, 'Usuario Ya Existe: Login');
  end if;

  INSERT INTO MSG_USER ( "ID", "NAME", "PASS", "LOGIN") VALUES ( seq_MSG_USER_id.nextval, name, pass,login );

  dbms_output.put_line('Usuario Creado: '||name);
  commit;

end;
/

当我使用exec插入用户时：

   exec new_user('testL1','testN1','testP1');
   exec new_user('testL2','testN2','testP2');

第二个失败，使用ORA-20013;这意味着（testL1 = testL2）= True。但是使用：

select count(*) from MSG_USER where NAME = 'testN2';

算上它等于0.我不知道为什么;有人可以帮我纠正我的手术吗？

Answer 1

您认为NAME = name的（逻辑）值是什么？

我可以看到你如何能够犯这个错误......也许你在C语言或类似语言中长大，资本化很重要。在SQL和PL / SQL中不是这样。

不要对表列和过程参数使用相同的名称。并了解PL / SQL对象名称不区分大小写。对于此过程，请更改 - 例如 - 更改为p_name，p_login等

Answer 2

您的绑定变量和列具有相同的名称。将绑定变量更改为具有不同的名称。

create or replace procedure new_user (
  i_login IN VARCHAR2, -- Use VARCHAR2 not VARCHAR
  i_name  IN VARCHAR2,
  i_pass  IN VARCHAR2
)
is
  rowsFound number;
  ERR_NULL            exception;
  ERR_NAME_TOO_LONG   exception;
  ERR_NAME_DUPLICATED exception;
  ERR_UNIQUE          exception;

  PRAGMA EXCEPTION_INIT(ERR_NULL,            -20001);
  PRAGMA EXCEPTION_INIT(ERR_NAME_TOO_LONG,   -20002);
  PRAGMA EXCEPTION_INIT(ERR_NAME_DUPLICATED, -20003);
  PRAGMA EXCEPTION_INIT(ERR_UNIQUE,          -20013);
begin
  if (i_login is null) or (i_name is null) or (i_pass is null) then
    raise_application_error(-20001, 'Datos de Usuario Nulos');
  end if; 

  if (LENGTH(i_name) > 100) then
    raise_application_error(-20002, 'Nombre Usuario Demasiado Largo');
  end if; 

  select count(*) into rowsFound from MSG_USER where NAME = i_name;
  if rowsFound >= 1 then
        raise_application_error(-20013, 'Usuario Ya Existe: Name');
  end if;

  select count(*) into rowsFound from MSG_USER where LOGIN = i_login;
  if rowsFound >= 1 then
        raise_application_error(-20013, 'Usuario Ya Existe: Login');
  end if;

  INSERT INTO MSG_USER ( "ID", "NAME", "PASS", "LOGIN") VALUES ( seq_MSG_USER_id.nextval, i_name, i_pass, i_login );

  dbms_output.put_line('Usuario Creado: '||i_name);
end;
/

此外，您should not put a COMMIT statement in the procedure - 在程序之后调用它，因为它允许您将多个过程调用捆绑到一个事务中并同时将它们全部回滚。

Oracle PL / SQL比较过程中的字符串

2 个答案: