Question

我想在Perl中匹配括号中的文本。我怎么能这样做？

这是来自official perlfaq的问题。我们是importing the perlfaq to Stack Overflow。

Answer 1

这是official FAQ answer减去任何后续修改。

您的第一次尝试可能应该是Text::Balanced模块，它位于Perl 5.8之后的Perl标准库中。它具有处理棘手文本的各种功能。 Regexp::Common模块还可以通过提供您可以使用的固定模式来提供帮助。

从Perl 5.10开始，您可以使用递归模式将平衡文本与正则表达式进行匹配。在Perl 5.10之前，您必须采用各种技巧，例如在(??{})序列中使用Perl代码。

这是使用递归正则表达式的示例。目标是捕获尖括号内的所有文本，包括嵌套尖括号中的文本。此示例文本有两个“主要”组：一个具有一个嵌套级别的组和一个具有两个嵌套级别的组。尖括号中有五个小组：

I have some <brackets in <nested brackets> > and
<another group <nested once <nested twice> > >
and that's it.

匹配平衡文本的正则表达式使用两个新的（到Perl 5.10）正则表达式功能。这些内容在perlre中介绍，此示例是该文档中的一个修改版本。

首先，将新的所有权+添加到任何量词，找到最长的匹配并且不回溯。这很重要，因为你想通过递归来处理任何尖括号，而不是回溯。小组[^<>]++找到一个或多个非尖角括号而无需回溯。

其次，新(?PARNO)指的是PARNO给出的特定捕获组中的子模式。在下面的正则表达式中，第一个捕获组找到（并记住）平衡文本，并且您需要在第一个缓冲区内使用相同的模式来通过嵌套文本。这是递归部分。 (?1)使用外部捕获组中的模式作为正则表达式的独立部分。

总而言之，你有：

#!/usr/local/bin/perl5.10.0

my $string =<<"HERE";
I have some <brackets in <nested brackets> > and
<another group <nested once <nested twice> > >
and that's it.
HERE

my @groups = $string =~ m/
        (                   # start of capture group 1
        <                   # match an opening angle bracket
            (?:
                [^<>]++     # one or more non angle brackets, non backtracking
                  |
                (?1)        # found < or >, so recurse to capture group 1
            )*
        >                   # match a closing angle bracket
        )                   # end of capture group 1
        /xg;

$" = "\n\t";
print "Found:\n\t@groups\n";

输出显示Perl找到了两个主要组：

Found:
    <brackets in <nested brackets> >
    <another group <nested once <nested twice> > >

通过一些额外的工作，即使它们也位于其他尖括号中，您也可以使用尖括号中的所有组。每次获得平衡匹配时，删除其外部分隔符（即刚刚匹配的分隔符，因此不再匹配）并将其添加到要处理的字符串队列中。继续这样做，直到你没有匹配：

#!/usr/local/bin/perl5.10.0

my @queue =<<"HERE";
I have some <brackets in <nested brackets> > and
<another group <nested once <nested twice> > >
and that's it.
HERE

my $regex = qr/
        (                   # start of bracket 1
        <                   # match an opening angle bracket
            (?:
                [^<>]++     # one or more non angle brackets, non backtracking
                  |
                (?1)        # recurse to bracket 1
            )*
        >                   # match a closing angle bracket
        )                   # end of bracket 1
        /x;

$" = "\n\t";

while( @queue )
    {
    my $string = shift @queue;

    my @groups = $string =~ m/$regex/g;
    print "Found:\n\t@groups\n\n" if @groups;

    unshift @queue, map { s/^<//; s/>$//; $_ } @groups;
    }

输出显示所有组。最外面的匹配首先显示，嵌套匹配稍后显示：

Found:
    <brackets in <nested brackets> >
    <another group <nested once <nested twice> > >

Found:
    <nested brackets>

Found:
    <nested once <nested twice> >

Found:
    <nested twice>

我可以使用Perl正则表达式来匹配平衡文本吗？

1 个答案: