Question

我在C ++中有以下函数调用：

int strLength = 20;
char* name;

getName(name, strLength);

printf("name: %s\n", name);

并在Fortran：

subroutine getName(name) bind (c, name='GETNAME')
use,intrinsic :: iso_c_binding
implicit none
character, intent(out) :: name

name = 'Martin'
end subroutine getName

当我执行C ++例程时，输出为：name: M。现在，我想这是因为character, intent(out) :: name声明name变量的大小为1，但如果我将声明更改为：character(len=6), intent(out) :: name我收到此错误消息：Error: Character argument 'name' at (1) must be length 1 because procedure 'getname' is BIND(C) 。我也尝试了这个：character(len=6,kind=c_char), intent(out) :: name，并显示相同的错误消息。最后，我尝试了这个声明：character(c_char),dimension(6), intent(out) :: name，它会编译但会产生这样的结果：name: MMMMMM。

我的问题归结为：如何从Fortran返回字符串到C ++？

Answer 1

这种基于Fortran函数的方法干净整洁，在C例程中尚未设置字符串（或为其分配内存）时非常合适。请注意，您不需要传入字符串长度参数，也不需要使用假定大小的数组来构建/返回字符串值。¹

使用Fortran可分配字符串常量，以便此函数可以重用于任何字符串。

还会将一个整数参数传递给Fortran函数，以演示如何指示所需的响应应该是什么。

请注意，在此示例中，“intent（out）”用于指示在传入之前不需要定义整数参数，但可以在返回之前更新它。因此，您可以修改其值并将其返回给调用程序，以便它可以用作“返回代码”。

Fortran功能

! f_string.f90
! Called from C routine as:  `myString = get_string(rc)`

function get_string(c_rc) bind(c, name='get_string')
    use, intrinsic :: iso_c_binding
    implicit none
    integer(c_int), intent(out) :: c_rc           ! <- Pass by reference; acts as return code in this example.
    type(c_ptr) :: get_string                     ! <- C_PTR to pass back to C
    character(len=:), allocatable, target, save :: fortstring   ! <- Allocatable/any length is fine

    fortstring = "Append C_NULL_CHAR to any Fortran string constant."//C_NULL_CHAR
    get_string = c_loc(fortstring)                ! <- C_LOC intrinsic gets loc of our string.
    c_rc = 1                                      ! <- Set the return code value.
end function get_string

C程序

// c_string.c
#include <stdio.h>
#include <string.h>
#include <stdlib.h>

char *get_string(int *rc);              // <- The Fortran function signature.

int main(){
    int rc;                             // <- No value set.
    char *mynameptr;                    // <- Just a plain ol' char *, no memory allocation needed.

    mynameptr = get_string(&rc);

    printf("mynameptr=%s\n", mynameptr);
    printf("len =%d\n", strlen(mynameptr));
    printf("rc  =%d\n", rc);
    return rc;
}

编译，调用，输出：

ifort /c f_string.f90
icl c_string.c /link f_string.obj
c_string.exe
# example output: 
# mynameptr=Append C_NULL_CHAR to any Fortran string constant.
# len =48
# rc  =1

_{¹这也可以在没有警告的情况下干净地编译（the OP's solution会发生这种情况，而不会在我的评论中提出修改）。}

Answer 2

问题在于将等级n的字符数组分配给长度为n的字符标量，该问题已在this问题中解决。如下所示更改Fortran例程解决了这个问题。

解决方案

由于我在遗留系统中工作，我不得不采用下面所示的解决方案。显然它并不完全相同，但它仍然显示了一般结构。如果其他人也应该采用这种解决方案，你应该遵循Matt P评论中的建议。

虽然这是我所采用的解决方案，但我觉得Matt P的答案是问题标题中所述的一般问题的更好解决方案，这就是为什么我接受了这个答案。

<强> C ++

int strLength = 20;
char* name = new char[strLength];   
getName(name, strLength);    
printf("name: %s\n", name);

<强>的Fortran

subroutine getName(name) bind (c, name='GETNAME')
use,intrinsic :: iso_c_binding
implicit none
character(c_char),dimension(20), intent(out) :: name
character(20) :: fName

fName = 'Martin'//c_null_char

do j=1,len(fName )
  name(j) = fName (j:j)  
enddo

end subroutine getName

将字符串从Fortran返回到C ++

2 个答案:

解决方案