Question

我正在尝试创建一个动态User_form，其中所有Controls都是在运行时创建的。

我有2个组合框，第一组组合框是＆＃34; Catgeory＆＃34; （CatCBArr），第二组组合框是＆＃34;项＆＃34; （ItemCBArr）。

我想，一旦我从＆＃34;类别＆＃34;的第一个组合框中选择一个值，让我们说CatCBArr(0)，只有{{1}中的相关项目将显示。

问题：我无法根据第一个组合框中选择的值（{{1）弄清楚如何修改第二个组合框（ItemCBArr(0)） }}）

User_Form 代码（相关部分）

ItemCBArr(0)

cComboBox 类代码

CatCBArr(0)

GUI User_Form 屏幕截图

Answer 1

好的，这是基础知识。你的班级 cCombobox 我复制如下：

Private WithEvents ComboBoxEvents As MsForms.ComboBox
Private Sub ComboBoxEvents_Change()
    Select Case ComboBoxEvents.value
        Case "1":
            UserForm1.DependentBox.Clear
            UserForm1.DependentBox.AddItem "3"
            UserForm1.DependentBox.AddItem "4"
        Case "2":
            UserForm1.DependentBox.Clear
            UserForm1.DependentBox.AddItem "5"
            UserForm1.DependentBox.AddItem "6"
        Case Default:
            'Do Nothing
    End Select
End Sub
Public Property Let box(value As MsForms.ComboBox)
    Set ComboBoxEvents = value
End Property
Public Property Get box() As MsForms.ComboBox
    Set box = ComboBoxEvents
End Property

接下来，我创建了一个 UserForm1 ，它添加了2个组合框，其中一个我添加到cComboBox类型的局部变量中。

Public DependentBox As MsForms.ComboBox
Private InitialBox As cComboBox
Private Sub UserForm_Initialize()
    Dim cBox As MsForms.ComboBox
    Set InitialBox = New cComboBox

    Set cBox = Me.Controls.Add("Forms.ComboBox.1", "initial", True)
    With cBox
        .Left = 6
        .Width = 100
        .Height = 25
        .Top = 6
        .AddItem "1"
        .AddItem "2"
    End With
    InitialBox.box = cBox

    Set DependentBox = Me.Controls.Add("Forms.ComboBox.1", "dependent", True)
    With DependentBox
        .Top = 6
        .Left = 126
        .Height = 25
        .Width = 100
    End With
End Sub

即使这样可行，上面的方法也不是很干净，因为你的类不是自包含的 - 它必须要注意UserForm。更好的方法是链接类中的框，然后在初始化控件数组时从Userform传递它们。那就是：

cComboBox 类：

Private WithEvents p_ComboBoxEvents As MSForms.ComboBox
Private p_DependBox As MSForms.ComboBox
Private Sub p_ComboBoxEvents_Change()
    Select Case p_ComboBoxEvents.value
        Case "1":
            p_DependBox.Clear
            p_DependBox.AddItem "3"
            p_DependBox.AddItem "4"
        Case "2":
            p_DependBox.Clear
            p_DependBox.AddItem "5"
            p_DependBox.AddItem "6"
        Case Default:
            'Do Nothing
    End Select
End Sub
Public Property Let TriggerBox(value As MSForms.ComboBox)
    Set p_ComboBoxEvents = value
End Property
Public Property Get TriggerBox() As MSForms.ComboBox
    Set TriggerBox = p_ComboBoxEvents
End Property
Public Property Let DependBox(value As MSForms.ComboBox)
    Set p_DependBox = value
End Property
Public Property Get DependBox() As MSForms.ComboBox
    Set DependBox = p_DependBox
End Property

在这里，您可以看到已经在自包含的类中链接了这些框。在事件处理程序中，您可以为值等创建查找。然后在 UserForm1 代码中按如下方式初始化它们：

Option Explicit
Private LinkedComboBox As cComboBox
Private Sub UserForm_Initialize()
    Dim cBox As MSForms.ComboBox
    Set LinkedComboBox = New cComboBox

    Set cBox = Me.Controls.Add("Forms.ComboBox.1", "initial", True)
    With cBox
        .Left = 6
        .Width = 100
        .Height = 25
        .Top = 6
        .AddItem "1"
        .AddItem "2"
    End With
    LinkedComboBox.TriggerBox = cBox

    Set cBox = Me.Controls.Add("Forms.ComboBox.1", "dependent", True)
    With cBox
        .Top = 6
        .Left = 126
        .Height = 25
        .Width = 100
    End With
    LinkedComboBox.DependBox = cBox
End Sub

修改基于它需要是一个数组的事实，您可以修改userform，如下所示：

Option Explicit Private LinkedComboBox(0 To 4) As cComboBOx Private Sub UserForm_Initialize() Dim cBox As MSForms.ComboBox Dim i As Integer For i = 0 To 4 Set LinkedComboBox(i) = New cComboBOx Set cBox = Me.Controls.Add("Forms.ComboBox.1", "initial", True) With cBox .Left = 6 .Width = 100 .Height = 25 .Top = 6 + (i * 25) .AddItem "1" .AddItem "2" End With LinkedComboBox(i).TriggerBox = cBox Set cBox = Me.Controls.Add("Forms.ComboBox.1", "dependent", True) With cBox .Top = 6 + (i * 25) .Left = 126 .Height = 25 .Width = 100 End With LinkedComboBox(i).DependBox = cBox Next i End Sub

在数组中，您可以LinkedComboBox(i).DependBox和LinkedComboBox(i).TriggerBox访问每个框。您将不再需要这两个单独的数组，因为此LinkedComboBox数组中已包含所有内容

动态创建的用户表单，包含2个相关的组合框

1 个答案: