在boxplot中将框的背景设置为与gnuplot的特定颜色

Question

我收到了以下数据：

# id       min  1st quart     median  3rd quart        max          sum    std-dev name
  1    0.00029    0.02590    0.06331    0.12910    6.50177   1524.58705    0.13483 spec
  2    1.50041    1.59762    1.67226    1.79827   13.45151  26583.69935    0.48373 schema
  3    0.00206    0.01292    0.02505    0.09679  116.93156   5337.36854    2.06006 truss

以下gnuplot脚本：

set terminal png enhanced background rgb 'white' size 1920,1200 font "Verdana 10"
set output "charts/summary.png"
set boxwidth 0.2 absolute
set title "Validating all data"
set xrange[0:4]
set yrange[0.00005:50]
set logscale y
set grid y

set tics scale 0
set xtics rotate by -45
set xtics nomirror
set ytics nomirror
set border 2

set style fill solid 0.25 border -1
set style data boxplot


plot "data/summary" using 1:3:2:6:5:(0.6):xticlabels(9) with candlesticks title 'Quartiles' whiskerbars, \
         ''         using 1:4:4:4:4:(0.6) with candlesticks lt -1 notitle

其输出如下：

问题是我无法弄清楚如何在箱线图中设置方框的背景颜色。我只能通过删除set style fill solid 0.25 border -1行来打开和关闭填充颜色。

Answer 1

虽然关键字的名称并不是这样建议的，但linecolor似乎会影响框的颜色，例如：

plot "data/summary" using 1:3:2:6:5:(0.6):xticlabels(9) with candlesticks lc rgb 'blue' title 'Quartiles' whiskerbars, \
    ''         using 1:4:4:4:4:(0.6) with candlesticks lt -1 notitle