Question

我在导出宏时遇到问题，当它在同一个包中声明时会起作用，但在导入时则不行。我在Windows上使用Emacs，SLIME，Clozure。

包裹文件

(defpackage :tokenizer
  (:use :common-lisp)
  (:export :tokenize-with-symbols 
       :current-token 
       :advanze-token 
       :peek-token
       :with-token-and-peek
       :with-token))

(defpackage :csharp-parser
  (:use :common-lisp :tokenizer)
  (:import-from :tokenizer :with-token-and-peek :with-token))

Tokenizer文件

(in-package :tokenizer)

(defmacro with-token-and-peek (&body body) 
  `(let ((token (current-token tokenizer))
     (peek (peek-token tokenizer)))
     ,@body))

解析器文件

(in-package :csharp-parser)

(defun expression (tokenizer node-stack)
  (with-token-and-peek
   (cond ((is-number? token) (make-value-node "number" token))
         ((is-bool? token) (make-value-node "bool" token))
         ((is-identifier? token peek) (make-identifier-node tokenizer node-stack))
         (t (make-ast-node :identifier "bla")))))

在编译时给出错误：

csharpParser.lisp:265:3:
  warning: Undeclared free variable TOKENIZER::TOKENIZER (2 references)
           style-warning: Unused lexical variable TOKENIZER::PEEK
           style-warning: Unused lexical variable TOKENIZER::TOKEN
csharpParser.lisp:266:14:
  warning: Undeclared free variable TOKEN
etc etc etc

如果我在包中尝试宏扩展：csharp-parser

(macroexpand-1 '(with-token-and-peek tok))

(LET ((TOKENIZER::TOKEN (CURRENT-TOKEN TOKENIZER::TOKENIZER))
      (TOKENIZER::PEEK (PEEK-TOKEN TOKENIZER::TOKENIZER)))
  TOK)
T

就像我说的，如果我将宏移动到解析器文件，它编译并完美地工作。但是当我尝试将它重构为tokenizer文件并通过包系统导出它时会产生这些错误，因为它似乎将符号内化到调用包中。我通过冒号尝试了多种方法，但无法让它起作用。

如果有人能帮助我，我将非常感激。

Answer 1

宏中的符号TOKEN和PEEK位于TOKENIZER包中，而COND中的代码则使用CSHARP-PARSER中的符号包。有两种方法可以解决这个问题。

扩展使用代码所在的包中的符号。这可以通过在扩展宏的同时手动实现当前包中的符号来完成。例如：

(defpackage #:foo
  (:use #:cl)
  (:export #:aif))

(in-package #:foo)

(defmacro aif (test then &optional else)
  (let ((it (intern (symbol-name 'it))))
    `(let ((,it ,test))
       (if ,it ,then ,else))))

(in-package :cl-user)
(use-package :foo)
(aif (+ 3 3) it) ;=> 6

使用(intern (symbol-name 'it))代替(intern "IT")是一种避免问题的方法，以防lisp不将符号转换为大写。

让代码使用tokenizer包中的interned符号。这可以通过导出符号来完成。

(defpackage #:foo
  (:use #:cl)
  (:export #:aif
           #:it))

(in-package #:foo)

(defmacro aif (test then &optional else)
  `(let ((it ,test))
     (if it ,then ,else)))

(in-package :cl-user)
(use-package :foo)
(aif (+ 3 3) it) ;=> 6

缺点是宏的用户必须导入符号，因此他们不能使用宏的包限定名。

(defpackage #:foo
  (:use #:cl)
  (:export #:aif
           #:it))

(in-package #:foo)

(defmacro aif (test then &optional else)
  `(let ((it ,test))
     (if it ,then ,else)))

(in-package :cl-user)
(foo:aif (+ 3 3) it) ; Fails

Answer 2

之所以发生这种情况，是因为带有带中间符号的宏扩展为包含在TOKENIZER中插入符号的代码，而cond表达式只有在CSHARP-PARSER中插入的符号。宏扩展包含的任何符号（关键字或gensyms除外）都应该被插入。

下面的宏将把符号列表插入到同名变量中：

(defmacro with-interned-symbols (symbol-list &body body)
  "Interns a set of symbols in the current package to variables of the same (symbol-name)."
  (let ((symbol-list (mapcar (lambda (s)
                               (list s `(intern (symbol-name ',s))))
                             symbol-list)))
    `(let ,symbol-list ,@body)))

可以使用上述方法重新定义with-token-and-peek宏以避免这种不匹配：

(with-interned-symbols (token peek)
  (defmacro with-token-and-peek (&body body) 
    `(let ((,token (current-token tokenizer))
       (,peek (peek-token tokenizer)))
       ,@body)))

请注意，虽然隐喻宏可能是最明显的特殊情况，但这种情况可能发生在将新符号引入扩展的任何宏中，但关键字始终存在于关键字包中。

在常见的lisp包中导出照应宏

2 个答案: