Question

请考虑以下有关文本或链接层端口号的规范：

(require '[clojure.spec.alpha :as spec])

(spec/def ::text (spec/and string? not-empty))
(spec/valid? ::text "a")                ; => true
(spec/valid? ::text "")                 ; => false
(spec/def ::port (spec/and pos-int? (partial > 65535)))
(spec/valid? ::port 4)                  ; => true
(spec/valid? ::port 0)                  ; => false
(spec/def ::text-or-port (spec/or ::text ::port))
(spec/valid? ::text-or-port 5)          ; => true
(spec/valid? ::text-or-port "hi")       ; => false

出于某种原因，它只接受端口号而不是文本，为什么会这样？

Answer 1

可以在documentation中使用spec/conform找到理解此问题的关键。

(spec/conform ::text-or-port 5)
; => [:user/text 5]

问题是clojure.spec.alpha/or有一个与clojure.core/or不同的API，给定两个参数返回第一个真正的一个：

(#(or (string? %) (integer? %)) 5)      ; => true
(#(or (string? %) (integer? %)) "")     ; => true
(#(or (string? %) (integer? %)) :a)     ; => false

相反，它需要成对的标签和规格/谓词。由于即使是命名空间关键字也被接受为标签，因此OP中给出的::text-or-port规范仅与通过::port要求的规范匹配，并为其指定了标签::text。以下是我们想要匹配的正确规范：

(spec/def ::text-or-port (spec/or :text ::text
                                  :port ::port))
(spec/valid? ::text-or-port "hi")       ; => true
(spec/valid? ::text-or-port 10)         ; => true

为什么我的or-spec仅对给定规格之一有效？

1 个答案: