片段着色器

Question

我试图在WebGL中显示纹理的清晰轮廓。 我将纹理传递给我的片段着色器，然后使用局部导数来显示轮廓/轮廓，但是，它并不像我期望的那样平滑。

只是打印纹理而不进行处理按预期工作：

vec2 texc = vec2(((vProjectedCoords.x / vProjectedCoords.w) + 1.0 ) / 2.0,
            ((vProjectedCoords.y / vProjectedCoords.w) + 1.0 ) / 2.0 );
vec4 color = texture2D(uTextureFilled, texc);
gl_FragColor = color;

对于本地衍生品，它错过了一些优势：

vec2 texc = vec2(((vProjectedCoords.x / vProjectedCoords.w) + 1.0 ) / 2.0,
            ((vProjectedCoords.y / vProjectedCoords.w) + 1.0 ) / 2.0 );
vec4 color = texture2D(uTextureFilled, texc);
float maxColor = length(color.rgb);
gl_FragColor.r = abs(dFdx(maxColor));
gl_FragColor.g = abs(dFdy(maxColor));
gl_FragColor.a = 1.;

Answer 1

理论上，您的代码是正确的。

但实际上，大多数GPU都是在2x2像素的块上计算衍生物。 因此，对于这种块的所有4个像素，dFdX和dFdY值将是相同的。 （详细解释here）

这会导致某种混叠，你会随机错过一些形状轮廓的像素（这种情况发生在从2x2块的边界处发生从黑色到形状颜色的过渡时）。

要解决这个问题，并获得真实的每像素衍生物，您可以自己计算，这看起来像这样：

// get tex coordinates
vec2 texc = vec2(((vProjectedCoords.x / vProjectedCoords.w) + 1.0 ) / 2.0,
                 ((vProjectedCoords.y / vProjectedCoords.w) + 1.0 ) / 2.0 );

// compute the U & V step needed to read neighbor pixels
// for that you need to pass the texture dimensions to the shader, 
// so let's say those are texWidth and texHeight
float step_u = 1.0 / texWidth;
float step_v = 1.0 / texHeight;

// read current pixel
vec4 centerPixel = texture2D(uTextureFilled, texc);

// read nearest right pixel & nearest bottom pixel
vec4 rightPixel  = texture2D(uTextureFilled, texc + vec2(step_u, 0.0));
vec4 bottomPixel = texture2D(uTextureFilled, texc + vec2(0.0, step_v));

// now manually compute the derivatives
float _dFdX = length(rightPixel - centerPixel) / step_u;
float _dFdY = length(bottomPixel - centerPixel) / step_v;

// display
gl_FragColor.r = _dFdX;
gl_FragColor.g = _dFdY;
gl_FragColor.a = 1.;

一些重要的事情：

• 纹理不应使用mipmap
• 纹理min＆amp; mag过滤应设置为GL_NEAREST
• 纹理钳位模式应设置为钳位（不重复）

这是一个ShaderToy样本，证明了这一点：