Question

从我管理的oracle 10gR2 10.2.05数据库中提取BLOBS时出现性能问题。我有大约400个文件存储为BLOBS，我需要写入文件系统。以下是我的代码。当我执行这个程序时，前几个8个左右的文件会在几秒钟内被写入，并且从那里开始减速，在第一个8之后每隔40秒就有一个文件。对我来说这没有任何意义，为什么会前8个文件速度很快，但之后一切都变慢了。我尝试将其作为存储过程运行，将UTL_FILE.fopen更改为“wb”（写入二进制文件），并使用NFS安装的文件系统，以免妨碍数据库的性能。这些都没有产生任何影响。按照这个速度，我需要花费6个小时来提取平均每个大约1.5MB的400个文件。有没有人看到我的代码有什么问题或知道更好的方法吗？顺便说一句，我使用此示例代码http://www.oracle-base.com/articles/9i/ExportBlob9i.php作为起点。

感谢您的帮助！

DECLARE
  TYPE comment_text IS TABLE OF documents.comment_text%TYPE;
  TYPE localdata IS TABLE OF documents.localdata%TYPE;
  l_file UTL_FILE.FILE_TYPE;
  l_buffer RAW(32767);
  l_amount BINARY_INTEGER := 32767;
  l_pos INTEGER := 1;
  l_blob localdata;
  l_fname comment_text;
  l_blob_len INTEGER;
  l_x NUMBER := 1;
BEGIN
  SELECT comment_text, localdata
  BULK COLLECT INTO l_fname, l_blob
  FROM documents
  WHERE user_id='BILLYBOB';
  IF SQL%ROWCOUNT =0 THEN
    DBMS_OUTPUT.PUT_LINE('No records found!');
  ELSE
    FOR i IN l_fname.FIRST .. l_fname.LAST
    LOOP
      l_blob_len := DBMS_LOB.getlength(l_blob(i));
      DBMS_OUTPUT.PUT_LINE(l_blob_len);
      l_file := UTL_FILE.fopen('BLOBS',l_x || '_' || l_fname(i),'w', 32767);
      l_pos := 1;
      l_x := l_x + 1;
      WHILE l_pos < l_blob_len
      LOOP
        DBMS_LOB.read(l_blob(i), l_amount, l_pos, l_buffer);
        UTL_FILE.put_raw(l_file, l_buffer, TRUE);
        l_pos := l_pos + l_amount;
      END LOOP;
      UTL_FILE.fclose(l_file);
    END LOOP;
  END IF;
END;

Answer 1

我很确定你不应该在程序开始时将所有BLOB都提取到数组中。由于您读取了BLOB数据并且从未实际关闭任何lob定位器，因此Oracle必须将所有这些信息保留在内存中。我猜这是一个内存溢出的情况。

请改为尝试：

CURSOR cc IS (SELECT ...)
BEGIN
   OPEN cc;
   LOOP
      FETCH cc
         INTO l_fname, l_blob;
      EXIT WHEN cc%NOTFOUND;
      l_blob_len := DBMS_LOB.getlength(l_blob);
      DBMS_OUTPUT.PUT_LINE(l_blob_len);
      l_file := UTL_FILE.fopen('BLOBS', l_x || '_' || l_fname, 'w', 32767);
      l_pos  := 1;
      l_x    := l_x + 1;
      WHILE l_pos < l_blob_len LOOP
         DBMS_LOB.READ(l_blob, l_amount, l_pos, l_buffer);
         UTL_FILE.put_raw(l_file, l_buffer, TRUE);
         l_pos := l_pos + l_amount;
      END LOOP;
      UTL_FILE.fclose(l_file);
   END LOOP;
   CLOSE cc;
END;

Oracle BLOB提取非常慢

1 个答案: