Question

我有数据集，有国家，玉米和棉花。我想在SAS中创建一个新变量Corn_Pct（相对于该国玉米产量的州玉米产量的百分比）。 Cotton_pct也一样。数据样本:(数字不是真实的）

    State Corn Cotton
    TX    135  500
    AK    120  350
    ...

有人可以帮忙吗？

Answer 1

您可以使用简单的Proc SQL执行此操作。让数据集为“Test”，

Proc sql ;
create table test_percent as 
select *,
Corn/sum(corn) as Corn_Pct format=percent7.1,
Cotton/sum(Cotton) as Cotton_Pct format=percent7.1
from test
;
quit;

如果您有多列，则可以使用Arrays和do loops每次自动生成百分比。

Answer 2

我已计算Inner Query中的一列总数，然后使用Cross Join

在外部查询中使用该总计进行计算

嘿试试这个： -

 /*My Dataset */
    Data Test;
    input     State $  Corn  Cotton ;
    cards;
    TK 135 500
    AK 120 350
    CK 100 250
    FG 200 300
    run;

    /*Code*/

    Proc sql;
    create table test_percent as 
    Select a.*, (corn * 100/sm_corn) as Corn_pct, (Cotton * 100/sm_cotton) as Cotton_pct
    from test a
    cross join
    (
    select sum(corn) as sm_corn ,
    sum(Cotton) as sm_cotton
    from test
    ) b ;
    quit;

        /*My Output*/
 State Corn Cotton    Corn_pct     Cotton_pct
     TK 135  500      24.32432432   35.71428571
     AK 120  350      21.62162162   25
     CK 100  250      18.01801802   17.85714286
     FG 200  300      36.03603604   21.42857143

Answer 3

您可以使用proc means和data step

来替代

proc means data=test sum noprint;
    output out=test2(keep=corn cotton) sum=corn cotton;
quit;

data test_percent (drop=corn_sum cotton_sum);
    set test2(rename=(corn=corn_sum cotton=cotton_sum) in=in1) test(in=in2);
    if (in1=1) then do;
        call symput('corn_sum',corn_sum);
        call symput('cotton_sum',cotton_sum);
    end;
    else do;
        Corn_pct = corn/symget('corn_sum');
        Cotton_pct = cotton/symget('cotton_sum');
    output;
    end;
run;

使用列的总和，创建新的变量

3 个答案: