是否有一种聪明的方法可以简化以下样式表，以避免在每个变量之间只有一个变量发生变化时重复整个when块？
理想情况下，我想要这样的事情，在$i上循环6次：
<xsl:when test="$depth > $i">
[...]
<xsl:value-of select="substring($npath,($nlength - $i*2),1) - 1"/>
[...]
</xsl:when>
我正在使用XSLT 1.0。
XML输入
<?xml version='1.0'?>
<?xml-stylesheet type="text/xsl" href="stylesheet.xsl" version="1.0"?>
<root>
<item>Main_A
<item>Item_A</item>
<item>Item_B
<item>Subitem_A</item>
<item>Subitem_B</item>
</item>
<item>Item_C</item>
</item>
<item>Main_B
<item>Item_A
<item>Subitem_A</item>
</item>
<item>Item_B</item>
</item>
</root>
XSLT 1.0样式表
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="root">
<html>
<body>
<xsl:apply-templates select="item">
<xsl:with-param name="depth" select="1"/>
</xsl:apply-templates>
</body>
</html>
</xsl:template>
<xsl:template match="item">
<xsl:param name="depth" select="1"/>
<xsl:if test="$depth < 10">
<ul>
<li>
<xsl:text>path</xsl:text>
<xsl:call-template name="loopnumformat">
<xsl:with-param name="depth" select="$depth"/>
</xsl:call-template>
<xsl:text> = </xsl:text>
<xsl:apply-templates match="item">
<xsl:with-param name="depth" select="$depth + 1"/>
</xsl:apply-templates>
</li>
</ul>
</xsl:if>
</xsl:template>
<xsl:template name="loopnumformat">
<xsl:param name="depth" select="1"/>
<xsl:variable name="npath">
<xsl:number level="multiple" from="*[10]"/>
</xsl:variable>
<xsl:variable name="nlength">
<xsl:value-of select="string-length($npath)"/>
</xsl:variable>
<xsl:choose>
<xsl:when test="$depth > 2">
<xsl:text>:</xsl:text>
<xsl:value-of select="substring($npath,($nlength - 2*2),1) - 1"/>
<xsl:call-template name="loopnumformat">
<xsl:with-param name="depth" select="$depth - 1"/>
</xsl:call-template>
</xsl:when>
<xsl:when test="$depth > 1">
<xsl:text>:</xsl:text>
<xsl:value-of select="substring($npath,($nlength - 1*2),1) - 1"/>
<xsl:call-template name="loopnumformat">
<xsl:with-param name="depth" select="$depth - 1"/>
</xsl:call-template>
</xsl:when>
<xsl:when test="$depth > 0">
<xsl:text>:</xsl:text>
<xsl:value-of select="substring($npath,($nlength - 0*2),1) - 1"/>
<xsl:call-template name="loopnumformat">
<xsl:with-param name="depth" select="$depth - 1"/>
</xsl:call-template>
</xsl:when>
</xsl:choose>
</xsl:template>
</xsl:stylesheet>
HTML输出
<html>
<body>
<ul>
<li>path:0 = Main_A
<ul>
<li>path:0:0 = Item_A</li>
</ul>
<ul>
<li>path:0:1 = Item_B
<ul>
<li>path:0:1:0 = Subitem_A</li>
</ul>
<ul>
<li>path:0:1:1 = Subitem_B</li>
</ul>
</li>
</ul>
<ul>
<li>path:0:2 = Item_C</li>
</ul>
</li>
</ul>
<ul>
<li>path:1 = Main_B
<ul>
<li>path:1:0 = Item_A
<ul>
<li>path:1:0:0 = Subitem_A</li>
</ul>
</li>
</ul>
<ul>
<li>path:1:1 = Item_B</li>
</ul>
</li>
</ul>
</body>
</html>
答案 0 :(得分：3)
是否有一种聪明的方法可以简化以下样式表，以避免在每个变量之间只有一个变量发生变化时重复整个块？
这取决于具体情况，但在您的特定情况下，您可以采用的一种方法是将xsl:choose移到内部，以便在每种情况下相同的部分仅表示一次：
<xsl:text>:</xsl:text>
<xsl:choose>
<xsl:when test="$depth > 2">
<xsl:value-of select="substring($npath,($nlength - 2*2),1) - 1"/>
</xsl:when>
<xsl:when test="$depth > 1">
<xsl:value-of select="substring($npath,($nlength - 1*2),1) - 1"/>
</xsl:when>
<xsl:when test="$depth > 0">
<xsl:value-of select="substring($npath,($nlength - 0*2),1) - 1"/>
</xsl:when>
</xsl:choose>
<xsl:call-template name="loopnumformat">
<xsl:with-param name="depth" select="$depth - 1"/>
</xsl:call-template>
但是，如果它不能满足您的需求，您似乎会花费极大的时间来使用xsl:number。看起来你可以更简单地完成整个事情：
<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="root">
<html>
<body>
<xsl:apply-templates select="item" />
</body>
</html>
</xsl:template>
<xsl:template match="item">
<xsl:param name="path-prefix" select="'path'"/>
<!-- if there are fewer than nine ':' characters in the path prefix for
this item ... -->
<xsl:if test="string-length($path-prefix) - string-length(translate($path-prefix, ':', '')) < 9">
<xsl:variable name="my-path"
select="concat($path-prefix, ':', position() - 1)" />
<ul>
<li>
<xsl:value-of select="$my-path"/>
<xsl:text> = </xsl:text>
<xsl:apply-templates select="text()[1]"/>
<xsl:apply-templates select="item">
<xsl:with-param name="path-prefix" select="$my-path"/>
</xsl:apply-templates>
</li>
</ul>
</xsl:if>
</xsl:template>
</xsl:stylesheet>
也许你甚至可以摆脱xsl:if，似乎它可能已经存在以提供原始样式表中loopnumformat模板的限制 - 这个版本没有固有的深度局限性。请注意，它确实假设您要复制到输出文档中的文本节点将限制在每个<item>中的第一个，但是很容易修改样式表而不是复制它们。
答案 1 :(得分：2)
看起来你在这里过度工程了。您只是在寻找一种方法来计算前面的<item>个节点，递归文档树。
这个简单的转变：
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:template match="root">
<html>
<body>
<ul>
<xsl:apply-templates select="item" />
</ul>
</body>
</html>
</xsl:template>
<xsl:template match="item">
<li>
<xsl:text>path</xsl:text>
<xsl:apply-templates select="." mode="path" />
<xsl:text> = </xsl:text>
<xsl:value-of select="normalize-space(text()[1])" />
<xsl:if test="item">
<ul>
<xsl:apply-templates select="item" />
</ul>
</xsl:if>
</li>
</xsl:template>
<xsl:template match="item" mode="path">
<xsl:apply-templates select="parent::item" mode="path" />
<xsl:text>:</xsl:text>
<xsl:value-of select="count(preceding-sibling::item)" />
</xsl:template>
</xsl:stylesheet>
结果：
<html>
<body>
<ul>
<li>path:0 = Main_A
<ul>
<li>path:0:0 = Item_A</li>
<li>path:0:1 = Item_B
<ul>
<li>path:0:1:0 = Subitem_A</li>
<li>path:0:1:1 = Subitem_B</li>
</ul>
</li>
<li>path:0:2 = Item_C</li>
</ul>
</li>
<li>path:1 = Main_B
<ul>
<li>path:1:0 = Item_A
<ul>
<li>path:1:0:0 = Subitem_A</li>
</ul>
</li>
<li>path:1:1 = Item_B</li>
</ul>
</li>
</ul>
</body>
</html>