Question

<books>
    <book>
        <title fiction="true">Happy Potter</title>
        <author>J. K. Rowling, Colman, Adman</author>
        <price>29.99</price>
    </book>

    <book>
        <title fiction="true">The Hobbit</title>
        <author>J.R.R. Tolkien</author>
        <price>25.99</price>
    </book>
</books>

所以我只想检查作者是否超过1。如果这样做，我想在最后显示第一作者姓名+ et al。如果没有，它只显示作者姓名。

例如，第一作者值为J. K. Rowling, Colman, Adman。然后我想显示为J. K. Rowling et al。

到目前为止，我只是关于split（）但是大多数资源都在谈论使用递归模板。由于我是XSL的新手，我无法完全理解他们提供的代码。

任何建议和帮助都会非常感激。感谢。

POST XSL FILE

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/">
<html> 
<body>
<h2>My Books Collection</h2>

<xsl:variable name="eligible-books" select="/books/book[title/@fiction='true' and price &lt; 30]" />

<xsl:for-each select="$eligible-books">     
    <span id="title"><xsl:value-of select="title"/></span><br/>
    <span id="author"><xsl:value-of select="author"/></span><br/>
    <span id="price"><xsl:value-of select="price"/></span><br/><br/>
</xsl:for-each>   

<span id="total">Total: <xsl:value-of select="sum($eligible-books/price)"/></span>

</body>
</html>
</xsl:template>

Answer 1

这里不需要递归。试试这种方式：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="author[contains(., ',')]">
    <xsl:copy>
        <xsl:value-of select="substring-before(., ',')"/>
        <xsl:text> et al.</xsl:text>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

应用于您的输入示例，结果将是：

<?xml version="1.0" encoding="UTF-8"?>
<books>
  <book>
    <title fiction="true">Happy Potter</title>
    <author>J. K. Rowling et al.</author>
    <price>29.99</price>
  </book>
  <book>
    <title fiction="true">The Hobbit</title>
    <author>J.R.R. Tolkien</author>
    <price>25.99</price>
  </book>
</books>

加了：

在样式表中，更改：

<xsl:value-of select="author"/>

为：

<xsl:choose>
    <xsl:when test="contains(author, ',')">
         <xsl:value-of select="substring-before(author, ',')"/>
         <xsl:text> et al.</xsl:text>
    </xsl:when>
    <xsl:otherwise>
         <xsl:value-of select="author"/>
    </xsl:otherwise>
</xsl:choose>

XSL将值拆分为Array并检查是否大于1

1 个答案:

加了：