Question

我正在尝试执行下面提供的经典ASP代码下的For Each Next循环。

For Each node in xml.SelectSingleNode("/Root/Div").ChildNodes
 response.write node.SelectSingleNode("item").text
Next

但我接收错误为

变量未定义＆＃39;节点＆＃39;，800a01f4

我想要处理的XML如下所示

<Root>
  <div>
   <div><item>I1</item></div>
   <div><item>I2</item></div>
   <div><item>I3</item></div>
   <div><item>I4</item></div>
  </div>
</Root>

Answer 1

完成这项工作：

Option Explicit

Dim sXML : sXML = Join(Array( _
    "<Root>" _
   , "<div>" _
   ,   "<div><item>I2</item></div>" _
   ,   "<div><item>I1</item></div>" _
   ,   "<div><item>I3</item></div>" _
   ,   "<div><item>I4</item></div>" _
   ,  "</div>" _
   , "</Root>"))
Dim oXML : Set oXML = CreateObject("MSXML.DOMDOCUMENT")
oXML.loadXML sXML
Dim oNode ' Uncomment to get: Variable ist nicht definiert: 'oNode'
' try "/Root/Div" or "/Root/Div/div" or "/Root/div" to realize why those are
' bad XPath expressions given your "/Root/div/div/item" structure
For Each oNode In oXML.SelectNodes("/Root/div/div")
    WScript.Echo oNode.tagName, oNode.firstChild.tagName, oNode.firstChild.text
Next
' For Each iterates over a collection; .SelectSingleNode returns
' a single node (surprise, surprise)

输出：

cscript 43737831.vbs
div item I2
div item I1
div item I3
div item I4

了解哪些错误会导致您的哪些问题。

Answer 2

你在正确的轨道上刚刚发现评论中的一些错误we discussed。

After realising Option Explicit已设置在代码中未显示的位置，修复方法是添加

Dim node

下一个错误是一个简单的修复和一个非常常见的错误。

Object Required：'node.selectSingleNode（..）

node对象不是对象，因为xml.SelectSingleNode("/Root/Div").ChildNodes调用从未返回过。发生这种情况是因为XPath字符串不正确，需要完全遵循XML结构，以及元素中定义的任何情况。

下面是一个基于您的代码的示例，但只是为了使示例工作，但我怀疑只是从

更改XPath

/Root/Div

到

/Root/div

可以解决问题。

<%
Option Explicit

Dim xml_data : xml_data = Join( _
  Array( _
    "<Root>" _
    , "<div>" _
    ,   "<div><item>I2</item></div>" _
    ,   "<div><item>I1</item></div>" _
    ,   "<div><item>I3</item></div>" _
    ,   "<div><item>I4</item></div>" _
    ,  "</div>" _
    , "</Root>") _
  )

Dim xml : Set xml = Server.CreateObject("Microsoft.XMLDOM")
Dim node

Call xml.LoadXML(xml_data)

For Each node In xml.SelectSingleNode("/Root/div").ChildNodes
  Call Response.Write(node.SelectSingleNode("item").Text & "<br />")
Next
%>

输出：

I2
I1
I3
I4

经典ASP错误变量未定义

2 个答案: