Question

我正在为我的办公室创建一个打字游戏，无论谁想尝试提高他们的键盘打字技能。我的代码保持得分，如果输入正确或不正确，并且在stackoverflow社区（伟大的Compo）的帮助下，我的代码已得到改进。现在我正在尝试为用户添加难度选项。但我似乎遇到一个问题，使批量参考回到输入的难度并遵循正确的难度选项。我知道我可以使用IF和ELSE，但我仍然习惯了批处理的工作原理。

添加难度之前的代码版本1

@ECHO OFF

SET/A "correct=incorrect=0"

:START
CLS
COLOR 07
SET "num=%RANDOM%"
ECHO.
ECHO SCORE - CORRECT %correct%, INCORRECT %incorrect%
ECHO.
ECHO %num%
ECHO.
SET /P "INP= "
ECHO.
IF "%INP%"=="%num%" (
    COLOR 27
    ECHO CORRECT
    SET/A "correct+=1"
    PING -n 2 0.0.0.0 1>NUL
) ELSE (
    COLOR 47
    ECHO INCORRECT
    SET/A "incorrect+=1"
    PING -n 2 0.0.0.0 1>NUL
)
GOTO START

带有难度选项的代码版本1

@ECHO OFF

SET/A "correct=incorrect=0"

:STARTDIFF
ECHO DIFFICULTY?
ECHO.
ECHO EASY
ECHO HARD
ECHO.
SET /P "DIFF= "
IF "%DIFF%" EQU EASY GOTO STARTEASY
IF "%DIFF%" EQU HARD GOTO STARTHARD
::IF "%DIFF%" NEQ EASY GOTO STARTDIFF

: STARTEASY
CLS
COLOR 07
SET "num=%RANDOM%"
GOTO TEST

: STARTHARD
CLS
COLOR 07
SET "num=%RANDOM%%RANDOM%"
GOTO TEST

: TEST
ECHO.
ECHO SCORE - CORRECT %correct%, INCORRECT %incorrect%
ECHO.
ECHO %num%
ECHO.
SET /P "INP= "
ECHO.
IF "%INP%"=="%num%" (
    COLOR 27
    ECHO CORRECT
    SET/A "correct+=1"
    PING -n 2 0.0.0.0 1>NUL
) ELSE (
    COLOR 47
    ECHO INCORRECT
    SET/A "incorrect+=1"
    PING -n 2 0.0.0.0 1>NUL
)

ECHO %DIFF%>NUL
IF "%DIFF%" EQU EASY GOTO STARTEASY
IF "%DIFF%" EQU HARD GOTO STARTHARD
::IF "%DIFF%" NEQ EASY GOTO STARTDIFF

::GOTO START

如何告诉代码从一开始就引用设置难度并继续使用该难度？

道歉，我希望我提出正确的术语，以便更好地解释我正在尝试做的事情。

Answer 1

尝试运行此代码，稍作修改。

@echo off

SET/A "correct=incorrect=0"

:STARTDIFF
ECHO DIFFICULTY?
ECHO.
ECHO EASY
ECHO HARD
ECHO.
SET /P "DIFF= "
IF "%DIFF%" EQU EASY GOTO STARTEASY
IF "%DIFF%" EQU HARD GOTO STARTHARD
::IF "%DIFF%" NEQ EASY GOTO STARTDIFF

:STARTEASY
SET X="EASY"
CLS
COLOR 07
SET "num=%RANDOM%"
GOTO TEST

:STARTHARD
SET X="HARD"
CLS
COLOR 07
SET "num=%RANDOM%%RANDOM%"


:TEST
ECHO.
ECHO SCORE - CORRECT %correct%, INCORRECT %incorrect%
ECHO.
ECHO %num%
ECHO.
SET /P "INP= "
ECHO.
IF "%INP%"=="%num%" (
    COLOR 27
    ECHO CORRECT
    SET/A "correct+=1"
    PING -n 2 0.0.0.0 1>NUL
) ELSE (
    COLOR 47
    ECHO INCORRECT
    SET/A "incorrect+=1"
    PING -n 2 0.0.0.0 1>NUL
)
IF %X%=="EASY" GOTO STARTEASY
IF  %X%=="HARD" GOTO STARTHARD
pause

Answer 2

if是非常文字的，并且两个参数必须完全相同才能被声明为相等。

因此，例如

IF "%DIFF%" EQU EASY GOTO STARTEASY

应该是

IF "%DIFF%" EQU "EASY" GOTO STARTEASY

或更好，

IF /I "%DIFF%" EQU "EASY" GOTO STARTEASY

使得比较不区分大小写。

但请注意，由于您要为变量x分配带引号的字符串，因此该比较是正确的。

也许你应该学习子程序。

:STARTEASY
CLS
COLOR 07
SET "num=%RANDOM%"
call :TEST
goto starteasy

然后删除例程if中的最后2 :test个语句，并使用pause行跟随goto :eof（毫无疑问是临时调试）。这会导致例程返回call之后的语句。

实际上，goto :eof并不是严格要求的，只是好的做法，这样如果你添加更多例程，你就不会从一个例程流到另一个例程。

请注意冒号很重要。 call :somelabel在此批处理文件中的标签somelabel处执行例程。 call somelabel（没有冒号）执行名为somelabel的外部可执行文件。

:中的:eof也很重要 - cmd将其理解为“此文件的结尾”

Answer 3

我不确定你为什么决定将结构完全改回一系列GOTO：

试试这个：

@ECHO OFF

ECHO DIFFICULTY?
ECHO.
ECHO 1. EASY
ECHO 2. HARD
ECHO.
CHOICE /C 12
SET "LEVEL=%ERRORLEVEL%"
SET/A "correct=incorrect=0"

:START
CLS
COLOR 07
IF "%LEVEL%"=="2" (Set "num=%RANDOM%%RANDOM%") ELSE SET "num=%RANDOM%" 
ECHO.
ECHO SCORE - CORRECT %correct%, INCORRECT %incorrect%
ECHO.
ECHO %num%
ECHO.
SET/P "INP= "
ECHO.
IF "%INP%"=="%num%" (
    COLOR 27
    ECHO CORRECT
    SET/A "correct+=1"
    TIMEOUT 1 1>NUL
) ELSE (
    COLOR 47
    ECHO INCORRECT
    SET/A "incorrect+=1"
    TIMEOUT 1 1>NUL
)
GOTO START

批号键盘输入游戏错误v2

3 个答案: