Question

我正在编写一个Mandelbrot Set实现，为了加快找出哪些点变为无穷大，我决定尝试使用ExecutorService并行检查这些点。

基本上计划是：

计算我需要找到的所有点
将每个点提供给服务
让服务将其结果转储到生成Atom vector的{{1}}
定期绘制代码抓取生成的结果，然后清除队列

我的问题是最后一点。如何安全地从原子中获取以前的结果，和重置它？

我想到了简单的方法：

(def draw-queue-A (atom []))

(defn grab-and-clear-queue []
  (let [results @draw-queue-A]
    (reset! draw-queue-A [])
    results))

但这看起来不安全。如果在取消引用和reset!之间添加了某些内容，则会丢失。

目前我已经确定的可恶的憎恶是：

(defn grab-and-clear-queue []
  (let [results (atom [])]
    (swap! draw-queue-A
           (fn [res] (reset! results res)
                     []))
    results))

但是使用原子来检索结果似乎很荒谬。

如何理智地检索原子的内容，和重置它而不会丢失任何结果？

Answer 1

目前有JIRA ticket处理此请求。与此同时，这会做你想要的，并且类似于补丁中的内容，尽管我只浏览了代码：

(defn reset-return-old!
  [atm new-value]
  (let [old-value @atm]
    (if (compare-and-set! atm old-value new-value)
      (do
        (.notifyWatches atm old-value new-value)
        old-value)
      (recur atm new-value))))

我们依赖CAS语义，就像swap!一样。我们有效地旋转以保证我们不会在读取和CAS之间中断（尽管我认为这仍然是ABA problem的牺牲品，但我认为在这种情况下这并不重要。）

我正在通知上面的手表 - 如果你没有，为了你的目的，你可以消除它和do块以进一步简化。

Answer 2

一个简单的答案是使用Clojure ref而不是atom。它允许您锁定多个函数调用的值（与swap不同）：

(ns tst.clj.core
  (:use clj.core clojure.test tupelo.test)
  (:require [tupelo.core :as t] ))
(t/refer-tupelo)
(t/print-versions)

(def results (ref []))
(future
  (doseq [i (range 10)]
    (dosync
      (Thread/sleep 20)
      (alter results t/append i))))

(defn get-and-clear []
  (dosync
    (let [curr-results @results]
      (ref-set results [])
      curr-results)))

(doseq [i (range 10)]
  (Thread/sleep 50)
  (spyx (get-and-clear)))

结果：

-------------------------------------
   Clojure 1.8.0    Java 1.8.0_111
-------------------------------------
(get-and-clear) => [0 1]
(get-and-clear) => [2 3]
(get-and-clear) => [4]
(get-and-clear) => [5 6]
(get-and-clear) => [7]
(get-and-clear) => [8 9]
(get-and-clear) => []
(get-and-clear) => []
(get-and-clear) => []
(get-and-clear) => []

其他选项包括使用clojure.core.async或a simple Java thread-safe queue.

中的队列

根据问题的格式，您还可以使用a Python-style generator function as described here.

获取原子的状态，并以原子方式重置它

2 个答案: