Question

我想在SAS中制作假人。我的计划是，每次公告日期。我想创建一个名为event = 2的变量，下一个变量也是（event = 2）以及之前的五个观察结果1 如果前5个观察结果和公告日期之后的第二天不是空的，那么所有这些都会被标记。按类别（以库存为例）

输出数据

date announcementdate event conflict
1115 . . .
2115 . . .
3115 . . .
4115 . . .
5115 . . .
6115 . 1 .
7115 . 1 .
8115 . 1 .
9115 . 1 .
10115 . 1 .
11115 1115 2 .
12115 . 2 .
13115 . .
14115 . 1 .
16115 . 1 .
17115 . 1 .
18115 . 1 .
19115 . 1 .
20115 20115 2 
21115 . 1 Y
21115 . 1 Y
22115 22115 2 Y
23115 . 2 Y
24115 . .
25115 . .

如果现在切换到下一个库存，它应该重新开始，不考虑以前的观察结果。

我当前的代码是一个主要术语，因为我只将事件列与firstobs = 2合并。无论如何，这种5倍的滞后困扰了我以及之前有观察的冲突。

data want1 ; set have;;
if announcementdate ne . then event=0;
run;

data want2; merge want1 (firstobs=2) want1 (keep=event rename= (event=event2)); 
if event2=0 then event=0; 
if event2=0 then event=event2;
run;

感谢任何输入！

Answer 1

我的方法是首先解析数据集以确定范围是什么，使用_n_作为指标（而不是id）。然后你可以构建一个简单的起始范围并用它来构建一个格式（好吧，两个，一个用于1，一个用于2）。

然后，使用前瞻合并解析数据集（以获取下一个start值）并查看是否存在冲突;然后使用您的逻辑为冲突标记定义另一种格式。我的例子包含了这个逻辑;它可能会或可能不符合您的确切需求，因此您可能需要更多地考虑这个逻辑并修改它，因为它非常具体。

然后，您只需使用_n_作为输入应用格式。当然，确保原始数据集没有排序。

这是完整的代码。

data have;
input date announcementdate event_want conflict_want $;
datalines;
1115 . . .
2115 . . .
3115 . . .
4115 . . .
5115 . . .
6115 . 1 .
7115 . 1 .
8115 . 1 .
9115 . 1 .
10115 . 1 .
11115 1115 2 .
12115 . 2 .
13115 . . .
14115 . 1 .
16115 . 1 .
17115 . 1 .
18115 . 1 .
19115 . 1 .
20115 20115 2 .
21115 . 1 Y
21115 . 1 Y
22115 22115 2 Y
23115 . 2 Y
24115 . . .
25115 . . .
;;;;
run;

data for_fmt;
  set have nobs=nobs;
  length fmtname $16;
  fmtname = 'eventf';

  if _n_=1 then do;   *HLO='o' gives the 'other' value;
    start=.;
    end  =.;
    label = ' ';
    hlo='o';
    output;
  end;
  hlo=' ';

  if not missing(announcementdate) then do;
    start = max(1,_n_-5);
    end   = max(1,_n_-1);
    label='1';
    output;
    start = _n_;
    end   = min(_n_+1,nobs);
    label='2';
    output;
  end;
run;  *now we have a dataset of the ranges - but they overlap;

data for_fmt_conflicts;

  merge for_fmt(in=a) for_fmt(in=_in_next firstobs=2 keep=start rename=start=next_start); *look-ahead merge;
  retain new_start conflict_marker;
  if hlo='o' then do;    *again the 'other' row;
    output;
    fmtname='conflictf';
    output;
  end;
  else if end gt next_start and (_in_next) then do;   *if the next row will be a conflict, adjust the end back one and indicate where next should start;
    end = end-1;
    new_start = end+1;
    conflict_marker=1;
    output;
  end;
  else if conflict_marker=1 then do;  *if this is a conflict row type 1;
    start = new_start;
    output;
    fmtname='conflictf';
    label  ='Y';
    output;
    conflict_marker=2;
  end;
  else if conflict_marker=2 then do;  *if this is the 2s for a conflict row;
    output;
    fmtname='conflictf';
    label  ='Y';
    output;
    conflict_marker=0;
  end;
  else output;
run;
proc sort data=for_fmt_conflicts;  *must sort to get fmtnames grouped together;
  by fmtname start;
run;
proc format cntlin=for_fmt_conflicts;  *import formats;
quit;

data want;  *now apply formats;
  set have;
  event = put(_n_,eventf.);
  conflict = put(_n_,conflictf.);
run;

SAS：用冲突标记下一次和之前的观察

1 个答案: