gnuplot：如何使用dat文件中的值作为箭头的目标？

Question

我在RecettesInvestissement2017.dat

中有以下数据

Excédent de fonctionnement capitalisé FCTVA et TA Caution Emprunt Subvention aménagement RD124 (Amendeuix) Subvention travaux de voirie 2015 Subvention travaux de voirie 2016 Subvention travaux de voirie 2017 Emprunt salle des associations Autofinancement  
7.32 1.95 0.07 38.35 11.19 0.76 1.36 0.90 2.87 35.23

请注意，字符串中的单词用unbreackable空格分隔，第一行中的字符串用普通空格分隔。

我的绘图文件是这样的

clear
set style data histogram
set style histogram rowstacked
set boxwidth 2 absolute
set style fill solid border
set xrange [-2,14]
set yrange [0,110]
unset xtics
unset ytics
unset key
i=0
do for [name in "`head -1 'RecettesInvestissement2017.dat'"]{
i=i+1
set label i name at 6,5+6*i
set arrow i from 5.8,5+6*i to 1,5+6*i}
plot for [C=1:10] 'RecettesInvestissement2017.dat' u C 

目前结果如下

我仍然需要调整字体，但在此之前我想让箭头到达堆积条的相关部分的中心。我需要帮助。 谢谢。

Answer 1

如果我理解正确，您希望将箭头绘制到每个彩色区域的中心。您可以使用函数计算Y位置，并使用向量绘图：

cumul_Y=0. #cumulative height
f(x)=(cumul_Y=cumul_Y+x, cur_Y=cumul_Y-x/2., cur_Y)
#cur_Y is a Y position
plot for [C=1:10] 'RecettesInvestissement2017.dat' u C, \
for [C=1:10] 'RecettesInvestissement2017.dat' u (5.8):(5+6*C):(-4.8):(f(column(C))-5-6*C) w vectors lc rgb('black'), \
for [C=1:10] 'RecettesInvestissement2017.dat' u (7):(5+6*C):(word(names,C))  w labels left font 'Arial,10'

然后你可以在plot命令中添加另一个部分，用标签进行绘图。

这是完整的脚本，它适合我。您必须在数据文件的第一行的开头添加一个字符#和空格。

set term png size 1024,768
set output 'plot.png'
set style data histogram
set style histogram rowstacked
set boxwidth 2 absolute
set style fill solid border
set xrange [-2:14]
set yrange [0:110]
unset xtics
unset ytics
i=0
names="`head -1 'RecettesInvestissement2017.dat'`"
cumul_C=0.
f(x)=(cumul_C=cumul_C+x, cur_C=cumul_C-x/2., cur_C)
unset key
plot for [C=1:10] 'RecettesInvestissement2017.dat' u C, \
for [C=1:10] 'RecettesInvestissement2017.dat' u (5.8):(5+6*C):(-4.8):(f(column(C))-5-6*C) w vectors lc rgb('black'), \
for [C=1:10] 'RecettesInvestissement2017.dat' u (6):(5+6*C):(word(names,C+1)) w labels left font 'Arial,10'
unset output
reset

Answer 2

这是我用你的脚本得到的