Question

我会尽力解释这种情况。

我有以下数据库列：

oid - task - start - end - realstart - realend

我的要求是输出如下：

oid1 - task1 - start1 - end1
oid2 - task2 - start2 - end2

其中task1为task，task2为task + "real"，start1为start，start2为realstart，end1为end，end2为realend }

BUT

应始终创建第一行（这些start/end字段永远不会为空）只有在存在realstart和realend时才应创建第二行，这可能不是真的。

输入是6个数组（每列一个），输出必须是4个数组，如下所示：

#input oid,task,start,end,realstart,realend
#output oid,task,start,end

我正在考虑使用oid.each这样的东西，但我不知道如何在当前节点之后添加节点。订单在要求中很重要。

如有任何解释，请询问，谢谢！

Answer 1

如果您需要一个从一开始就不知道其大小的“数组”，则应使用List代替。但在Groovy中，这很容易使用。

以下是一个例子：

final int OID = 0
final int TASK = 1
final int START = 2
final int END = 3
final int R_START = 4
final int R_END = 5

List<Object[]> input = [
        //oid,     task, start, end, realstart, realend
        [ 'oid1', 'task1', 10, 20, 12, 21 ],
        [ 'oid2', 'task2', 30, 42, null, null ]
]

List<List> output = [ ]

input.each { row ->
    output << [ row[ OID ], row[ TASK ], row[ START ], row[ END ] ]
    if ( row[ R_START ] && row[ R_END ] ) {
        output << [ row[ OID ], row[ TASK ] + 'real', row[ R_START ], row[ R_END ] ]
    }
}

println output

哪个输出：

[[oid1, task1, 10, 20], [oid1, task1real, 12, 21], [oid2, task2, 30, 42]]

Answer 2

在您发表评论并了解到您不希望（或不能）更改输入/输出数据格式之后，这是另一种解决方案，您可以使用类对数据进行分组并使其更易于管理：< / p>

import groovy.transform.Canonical

@Canonical
class Input {
    String[] oids = [ 'oid1', 'oid2' ]
    String[] tasks = [ 'task1', 'task2' ]
    Integer[] starts = [ 10, 30 ]
    Integer[] ends = [ 20, 42 ]
    Integer[] realstarts = [ 12, null ]
    Integer[] realends = [ 21, null ]

    List<Object[]> getEntries() {
        // ensure all entries have the same size
        def entries = [ oids, tasks, starts, ends, realstarts, realends ]

        assert entries.collect { it.size() }.unique().size() == 1,
                'The input arrays do not all have the same size'

        return entries
    }

    int getSize() {
        oids.size() // any field would do, they have the same length
    }

}

@Canonical
class Output {
    List oids = [ ]
    List tasks = [ ]
    List starts = [ ]
    List ends = [ ]

    void add( oid, task, start, end, realstart, realend ) {
        oids << oid; tasks << task; starts << start; ends << end

        if ( realstart != null && realend != null ) {
            oids << oid; tasks << task + 'real'; starts << realstart; ends << realend
        }
    }
}

def input = new Input()
def entries = input.entries

def output = new Output()

for ( int i = 0; i < input.size; i++ ) {
    def entry = entries.collect { it[ i ] }
    output.add( *entry )
}

println output

安排数据的责任在Input类，而知道如何组织输出数据的责任在Output类。

运行此代码会打印：

Output([oid1, oid1, oid2], [task1, task1real, task2], [10, 12, 30], [20, 21, 42])

您可以使用toArray()，output从output.oids对象获取数组（实际上是列表，但如果在列表中调用output.tasks，则可以调用output.starts， output.ends和@Canonical。

ffmpeg -i source.mxf -nostats -filter_complex ebur128=dualmono=true:panlaw=-3.01dB -f null -注释只是让类实现equals，hashCode，toString等等......

如果您不明白，请在评论中提问。

Groovy，在当前节点

2 个答案: