Question

如果类别包含特定单词但我不知道为什么不起作用，我试图做一个更改背景颜色的快速XSL文件：（

<?xml version="1.0" encoding="UTF-8"?>
<?xml-stylesheet type="text/xsl" href="catalogo1.xsl"?>

<tienda>
<articulos>
    <articulo>
        <referencia ID="1">8354268</referencia>
        <descripcion>Zapatillas de montaña Arpenaz 50 Negro</descripcion>
        <departamento>Hombre</departamento>
        <Categoria >Montaña</Categoria>
        <colores>Negro Carbon / Gris Roca</colores>
        <tallas>De 39 a 48</tallas>
        <precio>Antes 19,99€ ahora 17,99€</precio>
        <foto>images/8354268.jpg</foto>
        <url>https://www.decathlon.es/zapatillas-de-montaa-arpenaz-50-negro--id_8354268.html</url>
    </articulo>
    <articulo>
        <referencia ID="2">8383624</referencia>
        <descripcion>CAMISETA DE DEPORTES DE RAQUETA ASICS SHOCKING NARANJA ASICS</descripcion>
        <departamento>Hombre</departamento>
        <Categoria>Fitness</Categoria>
        <colores>Azul, verde, naranja</colores>
        <tallas>S, M, L, XL</tallas>
        <precio>34,99€</precio>
        <foto>images/8383624.jpg</foto>
        <url>https://www.decathlon.es/camiseta-shocking-naranja-id_8383624.html</url>
    </articulo>
    <articulo>
        <referencia ID="3">8222527</referencia>
        <descripcion>CHAQUETA SOFTSHELL SIBIR 500 CAMOFLUO SOLOGNAC</descripcion>
        <departamento>Hombre</departamento>
        <Categoria>Montaña</Categoria>
        <colores>Estampado Naranja</colores>
        <tallas>S, M, L, XL</tallas>
        <precio>34,99€</precio>
        <foto>images/8222527.jpg</foto>
        <url>https://www.decathlon.es/polar-de-caza-de-hombre-softshell-sibir-500-id_8222527.html</url>
    </articulo>
</articulos>

这将是XSL文件：

 <?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" 
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:template match="/">
<html>
  <head></head>


  <body>                                    
    <h1>Test</h1>

    <table border="1">                                  
        <tr bgcolor="green">                                
            <th>Reference</th>
            <th>Description</th>
            <th>Departament</th>
            <th>Categorie</th>
        </tr>                               
    <xsl:for-each select="tienda/articulos/articulo">   

        <!--- Error 
        <xsl:if test="Categoria = Montaña">
        <td bgcolor="#00FF00"> 
        Error -->

        <xsl:sort select="departamento"/>   
        <tr>                                
            <td>
                <xsl:value-of select="referencia"/>
            </td>
            <td>
                <xsl:value-of select="descripcion"/>
            </td>
            <td>
                <xsl:value-of select="departamento"/>
            </td>
            <td>
                <xsl:value-of select="Categoria"/>
            </td>               
        </tr>   

        <!--- Error 
        </td>
        </xsl:if> 
         Error -->

    </xsl:for-each>
    </table>                                

  </body>
</html>

有没有人知道我为什么得到这个代码的错误而不是改变td的颜色？

enter image description here

非常感谢您的帮助

Answer 1

如果我猜对了，你想做：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="/">
    <html>
        <head/>
        <body>                                  
            <h1>Test</h1>
            <table border="1">                                  
                <tr bgcolor="green">                                
                    <th>Reference</th>
                    <th>Description</th>
                    <th>Departament</th>
                    <th>Categorie</th>
                </tr>                               
                <xsl:for-each select="tienda/articulos/articulo">   
                    <xsl:sort select="departamento"/>   
                    <tr>    
                        <xsl:if test="Categoria='Montaña'">
                            <xsl:attribute name="bgcolor">#00FF00</xsl:attribute>
                        </xsl:if>
                        <td>
                            <xsl:value-of select="referencia"/>
                        </td>
                        <td>
                            <xsl:value-of select="descripcion"/>
                        </td>
                        <td>
                            <xsl:value-of select="departamento"/>
                        </td>
                        <td>
                            <xsl:value-of select="Categoria"/>
                        </td>               
                    </tr>   
                </xsl:for-each>
            </table>                                
        </body>
    </html>
</xsl:template>

</xsl:stylesheet>

这会测试Categoria的值是否为字符串 "Montaña"（请注意添加的单引号），并在整个行中添加bgcolor属性测试返回true。

有没有人知道我为什么得到这个代码而不是更改错误 td的颜色？

因为xsl:sort必须是其父元素的第一个子元素。这并不是说如果你改变指令的顺序，它就会起作用。正如我在评论中所说，尝试将整行包装在td元素中是没有意义的。只有在条件为真时，它才会输出行。

XSL：IF颜色未更新XSLT

1 个答案: