Question

我正在尝试使用以下代码加密和解密：

declare @decryptedValue nvarchar(4000)
declare @encryptedValue varbinary(8000)

SET @encryptedValue  = ENCRYPTBYPASSPHRASE('SQL SERVER 2008','SomeValue')
Set @decryptedValue = DECRYPTBYPASSPHRASE('SQL SERVER 2008',@encryptedValue)

print @decryptedValue

但是解密的值不是我传入的（'SomeValue'），而是一些加密的字符潓敭畲e e。

奇怪的是，如果我创建两个函数，如下所示：

 CREATE FUNCTION dbo.Encrypt(@str nvarchar(4000))
    RETURNS varbinary(8000)
    AS BEGIN 
     DECLARE @res varbinary(8000)
     SET @res = ENCRYPTBYPASSPHRASE('SQL SERVER 2008',@str)
     RETURN (@res)
     END
    GO



    CREATE FUNCTION dbo.Decrypt(@encrypt varbinary(8000))
    RETURNS nvarchar(4000)
    AS
    BEGIN 
     DECLARE @res nvarchar(4000)
     SET @res = DECRYPTBYPASSPHRASE('SQL SERVER 2008',@encrypt)
     RETURN(@res)
    END
    GO


declare @x nvarchar(4000)
declare @code varbinary(8000)
SET @code =   dbo.Encrypt('SomeValue')
Print @code
set @x = dbo.Decrypt(@code)
print @x

我错过了什么？

Answer 1

问题是您正在加密varchar值并将解密后的值转换为nvarchar。这两种数据类型具有不同的字节结构。它很容易修复（字面意思是一个字符）：

declare @decryptedValue nvarchar(4000)
declare @encryptedValue varbinary(8000)

SET @encryptedValue  = ENCRYPTBYPASSPHRASE('SQL SERVER 2008',N'SomeValue') --note the "N" before "N'SomeValue'"
Set @decryptedValue = DECRYPTBYPASSPHRASE('SQL SERVER 2008',@encryptedValue)

print @decryptedValue

至于它为什么与你的函数一起工作，因为函数的参数本身是打字的，你得到一个隐式转换。因此，当您向'SomeValue'函数提供Encrypt时，它会转换为nvarchar版本，将传递给encryptbypassphrase()。

ENCRYPTBYPASSPHRASE和DECRYPTBYPASSPHRASE未返回正确的值

1 个答案: