Question

在Practical Common Lisp的第8章末，Peter Seibel展示了once-only宏。其目的是通过用户定义的宏中的变量评估来缓解一些微妙的问题。注意我现在并没有试图理解这个宏如何工作，就像在其他一些帖子中一样，但是如何正确使用它：

(defmacro once-only ((&rest names) &body body)
  (let ((gensyms (loop for n in names collect (gensym))))
    `(let (,@(loop for g in gensyms collect `(,g (gensym))))
      `(let (,,@(loop for g in gensyms for n in names collect ``(,,g ,,n)))
        ,(let (,@(loop for n in names for g in gensyms collect `(,n ,g)))
           ,@body)))))

以下是一个示例（不正确）的人为宏，试图展示几个变量评估问题。它声称通过某个delta迭代一系列整数，返回范围：

(defmacro do-range ((var start stop delta) &body body)
  "Sample macro with faulty variable evaluations."
  `(do ((,var ,start (+ ,var ,delta))
        (limit ,stop))
       ((> ,var limit) (- ,stop ,start))
     ,@body))

例如，(do-range (i 1 15 3) (format t "~A " i))应打印1 4 7 10 13，然后返回14。

问题包括1）第二次出现limit的潜在捕获，因为它作为自由变量出现，2）可能捕获绑定变量limit的初始出现，因为它发生表达式以及宏参数中出现的其他变量，3）无序评估，因为delta将在stop之前进行评估，即使stop出现在delta之前在参数列表中，以及4）多个变量评估，因为stop和start被评估多次。据我了解，once-only应解决这些问题：

(defmacro do-range ((var start stop delta) &body body)
  (once-only (start stop delta limit)
    `(do ((,var ,start (+ ,var ,delta))
          (limit ,stop))
         ((> ,var limit) (- ,stop ,start))
       ,@body)))

但是，(macroexpand '(do-range (i 1 15 3) (format t "~A " i)))抱怨limit是未绑定的变量。如果我切换到with-gensyms，那应该解决问题1＆amp;只有上面的2，扩张没有发生。

这是once-only宏的问题吗？ once-only真的能解决上面列出的所有问题（也许是其他问题）吗？

Answer 1

ONCE-ONLY宏

要删除N未使用的警告，我会将宏更改为：

(defmacro once-only ((&rest names) &body body)
  (let ((gensyms (loop for nil in names collect (gensym))))
                           ; changed N to NIL, NIL is ignored
    `(let (,@(loop for g in gensyms collect `(,g (gensym))))
      `(let (,,@(loop for g in gensyms for n in names collect ``(,,g ,,n)))
        ,(let (,@(loop for n in names for g in gensyms collect `(,n ,g)))
           ,@body)))))

此宏的目的是确保表达式仅按定义的顺序进行一次计算。为此，它将引入新的未处理变量，并将评估结果与这些变量绑定。在宏内部，新变量可用。提供宏本身是为了使编写宏更容易。

在DO-RANGE中使用ONCE-ONLY

您使用ONCE-ONLY的示例：

(defmacro do-range ((var start stop delta) &body body)
  (once-only (start stop delta limit)
    `(do ((,var ,start (+ ,var ,delta))
          (limit ,stop))
         ((> ,var limit) (- ,stop ,start))
         ,@body)))

为什么LIMIT列表中有once-only？那里limit未定义。在LIMIT表单中使用ONCE-ONLY作为符号，但在外面没有绑定。

ONCE-ONLY期望名称列表是符号列表，并且这些名称绑定到表单。在您的情况下，limit是一个符号，但未定义。

我们需要从名称列表中删除limit：

(defmacro do-range ((var start stop delta) &body body)
  (once-only (start stop delta)
    `(do ((,var ,start (+ ,var ,delta))
          (limit ,stop))
         ((> ,var limit) (- ,stop ,start))
         ,@body)))

现在，如何处理LIMIT？鉴于once-only为名称提供了绑定，包括STOP，我们可以删除符号LIMIT并将其替换为,stop：

(defmacro do-range ((var start stop delta) &body body)
  (once-only (start stop delta)
    `(do ((,var ,start (+ ,var ,delta)))
         ((> ,var ,stop) (- ,stop ,start))
       ,@body)))

示例：

CL-USER 137 > (pprint
               (macroexpand
                '(do-range (i 4 10 2)
                   (print i))))

(LET ((#1=#:G2170 4)
      (#3=#:G2171 10)
      (#2=#:G2172 2))
  (DO ((I #1# (+ I #2#)))
      ((> I #3#) (- #3# #1#))
   (PRINT I)))

使用`once-only`宏

1 个答案: