Question

每当代理为某些他们正在执行的操作获取新值时，我希望他们将其添加到列表的末尾。如果列表上有十个或更多项，我希望它们删除列表中的第一个项目，以便列表按顺序具有代理看到的十个最新值。我怎么能这样做？（编辑：忘了问实际问题。）

我希望能够对列表中的每个项目应用数学运算，因此我不需要列出类似于单元格的列表，除非有一些简单的方法将数学运算应用到这个列表中的每个项目我都不知道。

Answer 1

让我们建立一个简单的例子，每只乌龟在每个刻度处以随机角度稍微右转，并将这些角度的历史存储在列表中：

turtles-own [ history ]

to setup
  clear-all
  create-turtles 3 [
    set history [] ; initialize history to an empty list
  ]
  reset-ticks
end

to go
  ask turtles [
    let angle random 5
    right angle
    ; add the angle of the most recent turn
    ; at the end of the list
    set history lput angle history
    if length history > 10 [
      ; remove the first item from the list
      set history but-first history
    ]
    forward 0.1
  ]
  tick
end

除非有一些简单的方法将数学运算应用于我不了解的列表中的每个项目，否则我不想要列出类似于单元格的列表。< / p>

我不知道你的意思是什么＆＃34;列表类似于单元格的列表＆＃34;但是像我们在这里建立的那个简单列表是迄今为止你可以使用的最好的东西你想做数学。

要对每个项目应用操作，请使用map。然后，您可以使用sum或mean等函数对整个列表进行操作。例如：

to do-math
  ask turtles [
    let doubled-history map [ a -> a * 2 ] history
    show history
    show doubled-history
    show mean doubled-history
  ]
end

（请注意，这使用NetLogo 6.0.1语法。）

让我们看一个示范：

observer> setup repeat 5 [ go ] do-math
(turtle 2): [4 3 2 1 2]
(turtle 2): [8 6 4 2 4]
(turtle 2): 4.8
(turtle 1): [4 0 1 1 4]
(turtle 1): [8 0 2 2 8]
(turtle 1): 4
(turtle 0): [2 0 4 1 0]
(turtle 0): [4 0 8 2 0]
(turtle 0): 2.8

NetLogo：在列表中添加和删除项目

1 个答案: