Question

我的代码的一部分计算尺寸大于300 X 300的矩阵的倒数（先前在代码中生成）。我想在代码中进一步使用反转矩阵的元素。为此尝试使用以下代码，尝试仅使用5X5矩阵进行测试：

use strict;
use warnings;
use Math::MatrixReal;
my @a=();                           #a is the matrix obtained
$a[0][0]=0.18761134;
$a[0][1]=0.010779401;               #Have hard-coded the values here till $a[4][4] 

my $ref_a = \@a;
my $b = Math::MatrixReal->new_from_rows($ref_a);
my $b_inv = $b->inverse();
print "\n Inverse is\n",$b_inv;                      #prints correct inverse
print "\n\nTest printing elements\n";
print $$b_inv[0][1][1],"\n";                         #prints the correct element

my $row_b=scalar(@{$b});   
print "Number of rows in b: ",$row_b,"\n";           #prints 6
my $col_b=@{$$b[0]};
print "Columns in b: ",$col_b,"\n";                  #prints 5

my $row_binv=scalar(@$b_inv);
print "Number of rows in b_inv: ",$row_binv,"\n";    #prints 3
my $col_binv=@{$$b_inv[0]};
print "Number of columns in b_inv ",$col_binv,"\n";  #prints 5

我无法理解

为什么b和b_inv的行数输出都是错误的？如何获得正确的行数值？
虽然引用数组的打印元素的语法是$$b_inv[1][1]，但在使用$$b_inv[0][1][1]

Answer 1

你正在创造一个 Math::MatrixReal 矩阵对象，然后将其作为简单的Perl数组访问。不加选择地在Perl对象内部进行探测是错误的，您必须使用文档中定义的方法

特别是你的陈述

print $$b_inv[0][1][1],"\n";    # prints the correct element

访问三维数组，如果不读取模块的代码，就无法知道“正确的元素”应该是什么

此修改设置一个5 x 5单位矩阵（将来，请提供我们可用于重现结果的数据）并采用其反转。值输出是使用我描述的对象方法派生的，并且都是正确的。请注意，对于Perl数组

，行和列的索引是从一个而不是零开始

use strict;
use warnings 'all';

use Math::MatrixReal;

my @arr = (
    [1, 0, 0, 0, 0],
    [0, 1, 0, 0, 0],
    [0, 0, 1, 0, 0],
    [0, 0, 0, 1, 0],
    [0, 0, 0, 0, 1],
);

my $ref_a = \@arr;
my $b = Math::MatrixReal->new_from_rows(\@arr);
my $b_inv = $b->inverse;

print "\nInverse is\n", $b_inv;
print "\n\nTest printing elements\n";
print $b_inv->element($_, $_), "\n" for 1 .. 5;

my ($row_b, $col_b) = $b->dim;;
print "Number of rows in b: $row_b\n";           # prints 5
print "Columns in b: $col_b\n";                  # prints 5

my ($row_binv, $col_binv) = $b_inv->dim;;
print "Number of rows in b_inv: $row_binv\n";    # prints 5
print "Number of columns in b_inv $col_binv\n";  # prints 5

输出

Inverse is
[  1.000000000000E+000  0.000000000000E+000  0.000000000000E+000  0.000000000000E+000  0.000000000000E+000 ]
[  0.000000000000E+000  1.000000000000E+000  0.000000000000E+000  0.000000000000E+000  0.000000000000E+000 ]
[  0.000000000000E+000  0.000000000000E+000  1.000000000000E+000  0.000000000000E+000  0.000000000000E+000 ]
[  0.000000000000E+000  0.000000000000E+000  0.000000000000E+000  1.000000000000E+000  0.000000000000E+000 ]
[  0.000000000000E+000  0.000000000000E+000  0.000000000000E+000  0.000000000000E+000  1.000000000000E+000 ]


Test printing elements
1
1
1
1
1
Number of rows in b: 5
Columns in b: 5
Number of rows in b_inv: 5
Number of columns in b_inv 5

如何计算Perl中引用数组的行数

1 个答案:

输出