Question

我不确定我是否正确地提出了这个问题，这就是为什么我无法在任何地方找到答案的原因。但基本上我需要将节点与另一个节点匹配，并使用兄弟节点作为值。这是一个例子

<group>
    <section>
      <reference>123</reference>
      <name>ABC</name>
    </section>
    <section>
      <reference>456</reference>
      <name>DEF</name>
   </section>
</group>
<element>
   <reference>123</reference>
   <price>20.00</price>
</element>

在我的XSL模板中，我想显示Price和Name，所以我需要将Element中的Reference与Section中的Reference匹配并显示Name。

ABC - 20.00

我该怎么做？

Answer 1

我需要将Section中的Reference与Section和Reference中的Reference相匹配显示名称。

XSLT有一个名为 key 的特殊功能，仅用于此目的。例如，以下样式表：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:key name="section" match="section" use="reference" />

<xsl:template match="/root">
    <output>
        <xsl:for-each select="element">
            <item>
                <xsl:value-of select="key('section', reference)/name"/>
                <xsl:text> - </xsl:text>
                <xsl:value-of select="price"/>      
            </item>
        </xsl:for-each> 
    </output>
</xsl:template>

</xsl:stylesheet>

应用于以下格式正确的输入时：

<强> XML

<root>
  <group>
    <section>
      <reference>123</reference>
      <name>ABC</name>
    </section>
    <section>
      <reference>456</reference>
      <name>DEF</name>
    </section>
  </group>
  <element>
    <reference>123</reference>
    <price>20.00</price>
  </element>
</root>

将返回：

<强>结果

<?xml version="1.0" encoding="UTF-8"?>
<output>
   <item>ABC - 20.00</item>
</output>

Answer 2

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">
    <xsl:output method="text" indent="yes"/>
    <xsl:key name="sss" match="section" use="reference"/>
    <xsl:template match="root">
        <xsl:for-each select="element">
            <xsl:value-of select="key('sss', reference)/name"/>
            <xsl:text> - </xsl:text>
            <xsl:value-of select="price"/>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

Answer 3

在XPath表达式上使用两个类似的谓词。在此示例中，假定名为<root>的根节点将包装其余的XML。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="xml" indent="yes" />

    <xsl:template match="/root">
      <xsl:value-of select="group/section[reference/text() = ../../element/reference/text()]/name" /> - <xsl:value-of select="element[reference/text() = ../group/section/reference/text()]/price" />
    </xsl:template>

</xsl:stylesheet>

输出为：

<?xml version="1.0"?>
ABC - 20.00

XSLT：如何通过另一个节点

3 个答案: