Question

我正在使用助手向我的项目添加firebase云消息，我在android studio构建项目时遇到以下错误消息：

错误：任务'：app：processDebugGoogleServices'的执行失败。请通过更新版本来修复版本冲突 google-services插件（有关最新版本的信息是可在 https://bintray.com/android/android-tools/com.google.gms.google-services/）或将com.google.android.gms的版本更新为9.8.0。

以下是构建文件：

顶层：

// Top-level build file where you can add configuration options common to all sub-projects/modules.  

buildscript {  
    repositories {  
        jcenter()  
    }  
    dependencies {  
        classpath 'com.android.tools.build:gradle:2.3.0'  

        // NOTE: Do not place your application dependencies here; they belong  
        // in the individual module build.gradle files  
        classpath 'com.google.gms:google-services:3.0.0'  
    }  
}  

allprojects {  
    repositories {  
        jcenter()  
    }  
}  

task clean(type: Delete) {  
    delete rootProject.buildDir  
}

应用级：

apply plugin: 'com.android.application'  

android {  
        compileSdkVersion 25  
        buildToolsVersion "25.0.0"  
        defaultConfig {  
        applicationId "in.ac.iitb.treeplantationapp"  
        minSdkVersion 21  
        targetSdkVersion 25  
        versionCode 1  
        versionName "1.0"  
        testInstrumentationRunner   "android.support.test.runner.AndroidJUnitRunner"  
    }  
    buildTypes {  
        release {  
            minifyEnabled false  
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'  
        }  
    }  
}  

dependencies {  
    compile fileTree(dir: 'libs', include: ['*.jar'])  
    androidTestCompile('com.android.support.test.espresso:espresso-core:2.2.2', {  
        exclude group: 'com.android.support', module: 'support-annotations'
    })  

    compile 'com.android.support:appcompat-v7:25.0.1'  
    compile 'com.android.volley:volley:1.0.0'  
    compile 'com.android.support:design:25.0.1'  
    compile 'com.google.android.gms:play-services-appindexing:9.8.0'  
    compile 'com.google.android.gms:play-services:10.0.0'  
    compile 'com.squareup.picasso:picasso:2.5.2'  
    compile 'com.google.firebase:firebase-messaging:10.0.1'  
    testCompile 'junit:junit:4.12'  
}  


apply plugin: 'com.google.gms.google-services'

Answer 1

您正在使用Google Play服务的不同版本：

compile 'com.google.android.gms:play-services-appindexing:9.8.0'  
compile 'com.google.android.gms:play-services:10.0.0'
compile 'com.google.firebase:firebase-messaging:10.0.1'

使用：

compile 'com.google.android.gms:play-services-appindexing:10.0.1'  
compile 'com.google.android.gms:play-services:10.0.1'
compile 'com.google.firebase:firebase-messaging:10.0.1'

添加com.google.gms.google-services时，版本冲突

1 个答案: