Question

我的Puppet代理是Windows Server 2012.我正在尝试向AD用户授予数据库权限。如果我尝试为其名称中不包含任何空格的AD用户分配权限，则脚本可以正常工作。早些时候，没有空格的用户名也没有用，但是当我添加一个额外的斜杠（'abc\\s_sql'）时，它对该用户起作用。对于带空格的用户名，尽管Puppet显示它已成功运行，但它仍无法正常工作。

[root@pe-server] cat grant_read.pp
define db::grant_read (
    $grant_read_params
) {
    $grant_read_ps = $grant_read_params[grant_read_ps]
    $grant_read_sql = $grant_read_params[grant_read_sql]
    $read_user = $grant_read_params[read_user]
    $db_name = $grant_read_params[db_name]

    utils::powershell_script { "Grant read access to user $read_user on $db_name":
        script    => $grant_read_ps,
        parameter => "$grant_read_sql $read_user $db_name",
    }
}


[root@pe-server] cat site.pp
node 'pe-agent.abc.com' {
    $grant_read_params_Support_PROD = {
        'grant_read_ps'  => 'c:/db/grant_read.ps1',
        'grant_read_sql' => 'c:/db/grant_read.sql',
        #'read_user'     => 'abc\\s_sql',
        'read_user'      => 'abc\\APP Support_PROD',
        'db_name'        => 'ABC_MASTER',
    }

    db::grant_read { "Granting read access to tom on some db":
        grant_read_params => $grant_read_params_Support_PROD
    }
}


[root@pe-server] cat powershell_script.pp
define utils::powershell_script (String $script, String $parameter = '') {
    $powershell = 'C:/Windows/System32/WindowsPowerShell/v1.0/powershell.exe -NoProfile -NoLogo -NonInteractive'
    exec { "Running $script on agent with parameter $parameter":
            command => "$powershell -File $script $parameter",
            logoutput => 'on_failure',
            timeout   => 900,
    }
}

在site.pp文件参数和grant_read.pp文件中尝试了几种排列和组合，但似乎没有任何工作。

我知道如何处理这个问题吗？

Answer 1

您需要在带有空格的参数周围加上双引号。单引号在此处不起作用，因为它们在执行PowerShell命令行的Windows环境中无效引用字符。而且由于你不能使用单引号字符串（以免Puppet不扩展变量），你必须使用反斜杠（对于Puppet）来转义嵌套的双引号。

基本上，这个：

"$grant_read_sql \"$read_user\" $db_name"

成为这样的字符串：

'c:/db/grant_read.sql "abc\APP Support_PROD" ABC_MASTER'

最后，当插入到PowerShell命令行中时，如下所示：

C:/Windows/System32/WindowsPowerShell/v1.0/powershell.exe -NoProfile -NoLogo -NonInteractive -File c:/db/grant_read.ps1 c:/db/grant_read.sql "abc\APP Support_PROD" ABC_MASTER

完全展开的命令行（见上文）必须采用允许直接从CMD或运行对话框运行它的形式。这意味着如果任何其他令牌（例如脚本路径）中有空格，那么该令牌也需要用双引号。

底线：您需要围绕参数执行Windows命令行的双引号，并使用反斜杠来转义Puppet的双引号字符串中的嵌套双引号。

使用空格处理名称

1 个答案: