Question

我有一个任务是在AT＆amp; T Assembly中编写一个程序，只要您想要使用Linux stdin和stdout的字节序列，就可以逐个读写。

它应该是一个Caesar密码扰码器，它只会向前一步改变大的拉丁字符（A，B，C，D，......）（所以像A到B，B到C，C到D，......，Z到A ）。

因此，程序会读取序列的第一部分，执行操作以更改字母而不更改其他字符，将更改的部分写入stdout，然后读取下一部分，并一次又一次地执行所有操作。

最后，它应该通过命令

运行程序来处理设置为stdin和stdout的文件

>./executable  >output.txt < input.txt

我现在能写的是能够读取一些字符，进行操作，打印输出并要求更多信息的程序。但是，如果在输入中放入的字符多于buf大小，则会崩溃。

以下是代码：

SYSCALL32 = 0x80 

EXIT = 1 
ERR_CODE = 0

STDIN = 0 
READ = 3 

STDOUT = 1 
WRITE = 4  

BUF_SIZE = 80 

.data
textin: .space BUF_SIZE
textout: .space BUF_SIZE

.global _start
_start:
mov $READ, %eax
mov $STDIN, %ebx
mov $textin, %ecx
mov $BUF_SIZE, %edx

int $SYSCALL32 # reading 80 characters (buf_size) of std input

cmp $0, %eax 
je exit #if 0 characters read exit

xorl %esi, %esi #clering iterator for loop

loop:
mov textin(%esi), %al #copying 1 character from textin buf to work with

cmp $'\n', %al
je out 
cmp $'A', %al
jl skip
cmp $'Z', %al
jg skip
je takeCareOfZ

add $1, %al
jmp skip

takeCareOfZ:
mov $'A', %al

skip:
movb %al, textout(%esi)
incl %esi
jmp petla

out:
mov $WRITE, %eax
mov $STDOUT, %ebx
mov $textout, %ecx
mov $BUF_SIZE, %edx

int $SYSCALL32 #writing 80 characters to std output

jmp _start

exit:
mov $EXIT, %eax
mov $ERR_CODE, %ebx

int $SYSCALL32

Answer 1

这是该程序的一个版本，它消除了与使用固定大小的缓冲区相关的复杂性。

        .text
        .global _start
_start:
        # read(STDIN_FILENO, buf, 1)
        movl    $1, %edx    # size_t nbyte
        movl    $buf, %ecx  # void *buf
        movl    $0, %ebx    # int filedes
        movl    $3, %eax    # sys_read
        int     $0x80

        cmp     $1, %eax    
        jne     bye         # EOF or read() error

        cmp     $'A', (%ecx)
        jl      output      # *buf < 'A'

        cmp     $'Z', (%ecx)
        jg      output      # *buf > 'Z'
        je      z           # *buf == 'Z'

        incl    (%ecx)      # *buf >= 'A' && *buf < 'Z'
        jmp     output

z:
        movl    $'A', (%ecx)

output:
        # write(STDOUT_FILENO, buf, 1)
        movl    $1, %ebx    # int filedes
        movl    $4, %eax    # sys_write
        int     $0x80
        jmp     _start

bye:
        # exit(0)
        movl    $0, %ebx    # int status
        movl    $1, %eax    # sys_exit
        int     $0x80

.data
buf:
        .byte 0

样品运行

$ gcc -nostdlib -m32 caesar.S -o caesar
$ ./caesar 
1234
1234
ABC1
BCD1
Z12BB
A12CC

使用gdb运行示例，一次一条指令。

连续阅读＆amp;在AT＆amp; T程序集中使用stdin和stdout编写

1 个答案: