Question

此问题不仅与MouseEvent.CLICK事件类型有关，而与AS3中已存在的所有事件类型有关。我读了很多关于自定义事件的内容，但直到现在我还无法弄清楚如何做我想做的事情。我将尝试解释，希望你理解：

以下是我的情况说明：

for(var i:Number; i < 10; i++){
    var someVar = i;
     myClips[i].addEventListener(MouseEvent.CLICK, doSomething);
}

function doSomething(e:MouseEvent){ /* */ }

但我希望能够将 someVar 作为参数传递给 doSomething 。所以我尝试了这个：

for(var i:Number; i < 10; i++){

    var someVar = i;
    myClips[i].addEventListener(MouseEvent.CLICK, function(){
        doSomething(someVar);
    });
}

function doSomething(index){ trace(index); }

这种作品，但不像我期望的那样。由于函数闭包，当实际触发MouseEvent.CLICK事件时， for 循环已经结束且 someVar 保持最后一个值，数字 9 < / em>在示例中。因此，每个影片剪辑中的每次点击都会调用 doSomething 传递 9 作为参数。而这不是我想要的。

我认为创建自定义事件应该有效，但是当我触发MouseEvent.CLICK事件并将参数传递给它时，我找不到触发自定义事件的方法。现在我不知道这是不是正确答案。

我该怎么做以及如何做？

Answer 1

您确实需要扩展事件类以使用额外参数创建自己的事件。将函数放在addEventListener（匿名函数）中是一个内存泄漏的方法，这是不好的。看看以下内容。

import flash.events.Event;

//custom event class to enable the passing of strings along with the actual event
public class TestEvent extends Event
{
    public static const TYPE1 :String = "type1";
    public static const TYPE2 :String = "type2";
    public static const TYPE3 :String = "type3";

    public var parameterText:String;

    public function TestEvent (type:String, searchText:String)
    {
        this.parameterText = searchText;
        super(type);
    }

}

创建新事件时，例如

dispatchEvent(new TestEvent(TestEvent.TYPE1, 'thisIsTheParameterText'))" ;

然后你可以像这样听

这个事件

someComponent.addEventListener(TestEvent.TYPE1, listenerFunction, true , 0, true);

并且在函数'listenerFunction'中，event.parameterText将包含你的参数。

因此，在myClips组件中，您将触发自定义事件并侦听该事件，而不是Click事件。

Answer 2

在不了解您的应用程序的情况下，您似乎更应该使用目标来传递参数，或者扩展MouseEvent。不过，前者更符合惯例。例如，如果您在“剪辑”对象上暴露了整数公共属性（无论它是什么）：

public class MyClip
{
   public var myPublicProperty:int;

   public function MyClip() { //... }
}

for (var i:int = 0; i < 10; i++)
{
   myClips[i].myPublicProperty = i;
   myClips[i].addEventListener(MouseEvent.CLICK, doSomething);
}

...然后，在您的事件监听器中，您可以使用事件的target或currentTarget属性检索该属性（在您的情况下可能是currentTarget）：

function doSomething(event:MouseEvent):void
{
   trace(event.currentTarget.myPublicProperty.toString());
}

应该这样做！祝你好运。

Answer 3

    private function myCallbackFunction(e:Event, parameter:String):void
    {
         //voila, here's your parameter
    }

    private function addArguments(method:Function, additionalArguments:Array):Function 
    {
         return function(event:Event):void {method.apply(null, [event].concat(additionalArguments));}
    }

    var parameter:String = "A sentence I want to pass along";
    movieClip.addEventListener(Event.COMPLETE, addArguments(myCallbackFunction, [parameter] ) );

利用AS3中的动态功能构造。

Answer 4

你可以通过从一个给出变量闭包的函数中获取你的处理程序来实现这一点，如下所示：

for (var i=0; i<5; i++) {
    myClips[i].addEventListener( MouseEvent.CLICK, getHandler(i) );
}

function getHandler(i) {
    return function( e:MouseEvent ) {
        test(i);
    }
}

function test( j ) {
    trace("foo "+j);
}

另外，至于为什么这会创建一个新的闭包，你可能想要检查this similar question的接受答案中的解释。

Answer 5

非常感谢这些有用的提示，这种技术比类解释更好理解。

对我来说，我刚开始使用这种技术来解决定时器数组和视口数组之间的链接关系，并通过在定时器事件中传递ID来经常更改其中的文本来更新状态。

像这样：

    var view:Object=[];

    for(var i:uint=0;i<Camera.names.length;i++){

    view[i]=getChildByName("Cam"+i);

    //_________ Add Text _________
    var tf:TextField = new TextField();
    tf.autoSize = TextFieldAutoSize.LEFT;
    tf.textColor=0xffffff;
    view[i].tf=view[i].addChild(tf);

    //_________ Add Timer _________
    var t:Timer = new Timer(1000);
    view[i].timer=t;
    view[i].timer.start();
    view[i].timer.addEventListener(TimerEvent.TIMER, addArg(i)); 
}

function addArg(adi:uint):Function {
    return function(event:TimerEvent):void {
        updatecamstatus(adi);
    }
}
function updatecamstatus(vH:uint):void {
   with (view[vH]){
    tf.text="Cam" + vH + "\n";
    tf.appendText("activityLevel: " + videosource.activityLevel + "\n"); 
    tf.appendText("motionLevel: " + videosource.motionLevel + "\n"); 
   }
}

Answer 6

我看到你的主要目标实际上并不是创建自定义MouseEvent.CLICK，而是将参数传递给函数。您无需复杂地创建或扩展任何内容。这是一种简单且无关闭的方法。

让你的功能如下：

function doSomething(index:Number):Function {
  return function(e:MouseEvent):void {
    // Use "e" and "index" here. They'll be unique for each addEventListener()
    trace(index);
  }
}

此技术可以与您可以使用addEventListener的任何AS3事件类型相关。

现在你可以像这样添加它：

var functionsDoSomething:Object;

for (var i:Number = 0; i < 10; i++) {
  var someVar:Number = i;
  functionsDoSomething[i] = doSomething(someVar);
  myClips[i].addEventListener(MouseEvent.CLICK, functionsDoSomething[i]);
}

doSomething(someVar)可以直接在addEventListener()上使用，但最好将其保存在变量中，因为您可以稍后以与添加它相同的方式将其删除：

for (i = 0; i < 10; i++) {
  myClips[i].removeEventListener(MouseEvent.CLICK, functionsDoSomething[i]);
}

常用的e.currentTarget.someCustomProperty适用于动态对象（即MovieClip），但会让你失望（即Sprite），迫使你为每种类型构建一个完整的自定义扩展对象/事件。

此解决方案处理每个“可听”对象和事件。 this answer有更多细节和示例。

如何在AS3中创建自定义MouseEvent.CLICK事件（将参数传递给函数）？

6 个答案: