Question

我有一个脚本，它会拉出我目录中的所有pm文件，并查找某些模式并将其更改为所需的值，我尝试了Tie :: File但它没有查找文件的内容

use File::Find;
use Data::Dumper qw(Dumper);
use Tie::File;
my @content;
find( \&wanted, '/home/idiotonperl/project/');

sub wanted {
    push @content, $File::Find::name;
return;  
}
my @content1 = grep{$_ =~ /.*.pm/} @content;
@content = @content1;
for my $absolute_path (@content) {
    my @array='';
    print $absolute_path;
    tie @array, 'Tie::File', $absolute_path or die qq{Not working};
    print Dumper @array;
    foreach my $line(@array) {
         $line=~s/PERL/perl/g;
    }
    untie @array;
 }

输出

 Not working at tiereplacer.pl line 22.
 /home/idiotonperl/main/content.pm

这不按预期工作（查看所有pm文件的内容），如果我尝试对我的家庭下的单个文件的某些测试文件执行相同的操作，则内容将被替换

  @content = ‘home/idiotonperl/option.pm’

它按预期工作

Answer 1

我不建议使用tie。下面这个简单的代码应该按照要求进行

use warnings;
use strict;
use File::Copy qw(move);    
use File::Glob ':bsd_glob';

my $dir = '/home/...';

my @pm_files = grep { -f } glob "$dir/*.pm";

foreach my $file (@pm_files) 
{
    my $outfile = 'new_' . $file;  # but better use File::Temp

    open my $fh,     '<', $file    or die "Can't open $file: $!";
    open my $fh_out, '>', $outfile or die "Can't open $outfile: $!";

    while (my $line = <$fh>)
    {
        $line =~ s/PERL/perl/g;
        print $fh_out $line;     # write out the line, changed or not
    }
    close $fh;
    close $fh_out;

    # Uncomment after testing, to actually overwrite the original file
    #move $outfile, $file  or die "Can't move $outfile to $file: $!";
}

来自File::Glob的glob允许您像在shell中一样指定文件名。请参阅接受元字符的文档。 :bsd_glob更适合处理文件名中的空格。 ^†

如果您需要递归处理文件，那么您确实需要一个模块。见File::Find::Rule

其余代码执行更改文件内容时必须执行的操作：复制文件。循环读取每一行，更改匹配的行，并将每行写入另一个文件。如果匹配失败，则s/不会对$line进行任何更改，因此我们只是复制那些未更改的内容。

最后，我们move使用File::Copy覆盖原始文件。

新文件是临时文件，我建议使用File::Temp创建它。

^† glob模式"$dir/..."允许具有特定名称的目录的注入错误。虽然这很不寻常，但使用escape sequence

会更安全

my @pm_files = grep { -f } glob "\Q$dir\E/*.pm";

在这种情况下，File::Glob不需要\Q，因为Date也会转义空格。

Answer 2

使用我最喜欢的模块解决方案：Path::Tiny。不幸的是，它不是核心模块。

use strict;
use warnings;
use Path::Tiny;

my $iter = path('/some/path')->iterator({recurse => 1});
while( my $p = $iter->() ) {
        next unless $p->is_file && $p =~ /\.pm\z/i;
        $p->edit_lines(sub {
            s/PERL/perl/;
            #add more line-editing
        });
        #also check the path(...)->edit(...) as an alternative
}

Answer 3

对我来说工作正常：

#!/usr/bin/env perl
use common::sense;
use File::Find;
use Tie::File;

my @content;

find(\&wanted, '/home/mishkin/test/t/');

sub wanted {
    push @content, $File::Find::name;
    return;
}

@content = grep{$_ =~ /.*\.pm$/} @content;

for my $absolute_path (@content) {
    my @array='';
    say $absolute_path;
    tie @array, 'Tie::File', $absolute_path or die "Not working: $!";

    for my $line (@array) {
        $line =~ s/PERL/perl/g;
    }

    untie @array;
}

绑定文件不适用于循环

3 个答案: